iniciar-programa
    define-nueva-instruccion g(n) como
        repetir n veces
            gira-izquierda;
    define-nueva-instruccion d(n) como
    inicio
        g(3);
        repetir precede(n) veces
        inicio
            deja-zumbador;

            repetir precede(n) veces
            inicio
                avanza;
                deja-zumbador;
            fin;
            g(2);
            repetir precede(n) veces
                avanza;
            g(3);
            avanza;
            g(3);
        fin;
        deja-zumbador;
        repetir precede(n) veces
        inicio
            avanza;
            deja-zumbador;
        fin;
        g(2);
        repetir precede(n) veces
            avanza;
        g(1);
        repetir precede(n) veces
            avanza;
        g(2);
    fin;
    define-prototipo-instruccion cosa(n);
    define-nueva-instruccion a(n) como
    inicio
        repetir n veces
            si frente-libre entonces
                avanza;
    fin;
    define-nueva-instruccion cuenta(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino
        inicio
            deja-zumbador;
            cosa(n);
        fin;
    fin;
    define-nueva-instruccion cosa(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            si no si-es-cero (n) entonces
            inicio
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                cosa(n);
                d(n);
            fin
            sino
            inicio
                cuenta(0);
            fin;
        fin
        sino
        inicio
            si frente-libre entonces
            inicio
                avanza;
                cosa(n);
                a(n);
            fin
            sino
            inicio
                g(2);
                mientras frente-libre hacer
                    avanza;
                g(1);
                si frente-libre entonces
                inicio
                    avanza;
                    si derecha-bloqueada entonces
                    inicio
                        g(1);
                        cosa(n);
                        g(2);
                        mientras frente-libre hacer
                            avanza;
                        g(1);
                        a(n);
                        g(1);
                    fin
                    sino
                    inicio
                        g(2);
                        avanza;
                        g(2);
                        g(1);
                        mientras frente-libre hacer
                            avanza;
                        g(3);
                        avanza;
                        g(1);
                        mientras derecha-bloqueada hacer
                            avanza;
                        g(3);
                        avanza;
                        mientras derecha-bloqueada hacer
                            avanza;
                        g(3);
                        avanza;
                        mientras derecha-bloqueada hacer
                            avanza;
                        g(3);
                        avanza;
                        g(1);
                    fin;
                fin
                sino
                inicio
                    mientras no-orientado-al-sur hacer
                        g(1);
                    mientras frente-libre hacer
                        avanza;
                    g(3);
                    mientras frente-libre hacer
                        avanza;
                    g(3);
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer
            g(1);
        repetir 49 veces
            si frente-libre entonces
                avanza;
        g(1);
        mientras frente-libre hacer
            avanza;
        g(2);
        cosa(0);
        apagate;
    termina-ejecucion
finalizar-programa
