iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion fila (n) como inicio
        este;
        repetir precede (n) veces
            avanza;
        si frente-libre entonces inicio
            sur;
            mientras frente-libre hacer
                avanza;
            este;
            avanza;
            norte;
        fin
        sino inicio
            sur;
            mientras frente-libre hacer
                avanza;
            oeste;
            mientras frente-libre hacer
                avanza;
            norte;
        fin;
    fin;
    define-nueva-instruccion blanco (n) como inicio
        repetir precede (n) veces
            avanza;
        si frente-libre entonces
            avanza;
    fin;
    define-nueva-instruccion negro (n) como inicio
        norte;
        repetir n veces inicio
            deja-zumbador;
            repetir precede (n) veces inicio
                avanza;
                deja-zumbador;
            fin;
            sur;
            repetir precede (n) veces
                avanza;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin
            sino inicio
                oeste;
                repetir precede (n) veces
                    avanza;
                norte;
            fin;
        fin;
        si no-junto-a-zumbador entonces inicio
            oeste;
            repetir n veces
                avanza;
            norte;
        fin;
        blanco (n);
    fin;
    define-nueva-instruccion guarda (n) como inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            si frente-libre entonces inicio
                avanza;
                guarda (n);
                negro (n);
            fin
            sino inicio
                norte;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                coge-zumbador;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    deja-zumbador;
                    sur;
                    avanza;
                    guarda (n);
                    fila (n);
                    negro (n);
                fin
                sino inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    norte;
                    negro (n);
                fin;
            fin;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                guarda (n);
                blanco (n);
            fin
            sino inicio
                norte;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                coge-zumbador;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    deja-zumbador;
                    sur;
                    avanza;
                    guarda (n);
                    fila (n);
                    blanco (n);
                fin
                sino inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    norte;
                    blanco (n);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion checa (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            checa (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            norte;
            avanza;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            sur;
            avanza;
            guarda (n);
        fin;
    fin;
    define-nueva-instruccion ancho como inicio
        si frente-libre y no-junto-a-zumbador entonces inicio
            avanza;
            ancho;
        fin
        sino inicio
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                norte;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                coge-zumbador;
                oeste;
                avanza;
                deja-zumbador;
                sur;
                avanza;
                ancho;
            fin
            sino inicio
                si junto-a-zumbador entonces inicio
                    checa (0);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion alto como inicio
        si frente-libre y no-junto-a-zumbador entonces inicio
            avanza;
            alto;
        fin
        sino inicio
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    alto;
                fin
                sino inicio
                    oeste;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    apagate;
                fin;
            fin
            sino inicio
                si junto-a-zumbador entonces inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                    fin
                    sino inicio
                        apagate;
                    fin;
                    oeste;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    mientras frente-libre hacer
                        avanza;
                    deja-zumbador;
                    sur;
                    avanza;
                    ancho;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion marca como inicio
        repetir 50 veces inicio
            si frente-libre entonces
                avanza;
        fin;
        este;
        alto;
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion revisa como inicio
        mientras junto-a-zumbador y frente-libre hacer
            avanza;
        si junto-a-zumbador entonces
            apagate;
        si algun-zumbador-en-la-mochila entonces
            deja-zumbador;
        si no-junto-a-zumbador entonces inicio
            apagate;
        fin
        sino inicio
            coge-zumbador;
            sur;
            mientras frente-libre hacer
                avanza;
            norte;
        fin;
    fin;
    define-nueva-instruccion kareloscopio como inicio
        revisa;
        marca;
    fin;
    inicia-ejecucion
        kareloscopio;
        apagate;
    termina-ejecucion
finalizar-programa