iniciar-programa

define-prototipo-instruccion comparar_distancias(a);

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion orientarse como inicio
    mientras izquierda-libre hacer gira-izquierda;
    deja-zumbador;
    mientras frente-libre hacer avanza;
    gira(2);
    si derecha-bloqueada entonces inicio
        mientras no-junto-a-zumbador hacer avanza;
    fin sino inicio
        mientras no-junto-a-zumbador hacer avanza;
        gira(2);
    fin;
    coge-zumbador;
fin;

define-nueva-instruccion buscar_puerta(a) como inicio
    deja-zumbador;
    si no si-es-cero(precede(a)) entonces deja-zumbador;
    si izquierda-libre y frente-libre entonces inicio
        gira(2);
        si frente-libre entonces inicio
            repetir precede(a) veces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                si frente-bloqueado entonces gira(3);
                avanza;
            fin;
            si frente-bloqueado entonces gira(3);
            si si-es-cero(precede(a)) entonces inicio
                gira(3);
                avanza;
                si junto-a-zumbador entonces apagate;
                gira(3);
                buscar_puerta(1);
            fin;
            comparar_distancias(precede(a));
            gira(2);
            repetir precede(a) veces inicio
                si frente-bloqueado entonces gira(1);
                avanza;
                deja-zumbador;
            fin;
            gira(1);
            avanza;
            si junto-a-zumbador entonces apagate;
            gira(3);
            buscar_puerta(1);
        fin sino inicio
            gira(2);
            avanza;
            buscar_puerta(sucede(a));
        fin;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            buscar_puerta(sucede(a));
        fin sino inicio
            gira(1);
            avanza;
            buscar_puerta(sucede(a));
        fin;
    fin;
fin;

define-nueva-instruccion comparar_distancias(a) como inicio
    si no si-es-cero(a) entonces inicio
        si derecha-libre y frente-libre entonces inicio
            gira(2);
            si frente-libre entonces inicio
                gira(1);
                avanza;
                si junto-a-zumbador entonces apagate;
                gira(3);
                buscar_puerta(1);
            fin sino inicio
                gira(2);
                avanza;
                deja-zumbador;
                comparar_distancias(precede(a));
                coge-zumbador;
                gira(2);
                avanza;
                gira(2);
            fin;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                deja-zumbador;
                comparar_distancias(precede(a));
                coge-zumbador;
                gira(2);
                avanza;
                gira(2);
            fin sino inicio
                gira(3);
                avanza;
                deja-zumbador;
                comparar_distancias(precede(a));
                coge-zumbador;
                gira(2);
                avanza;
                gira(3);
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion buscar_minotauro como inicio
    buscar_puerta(1);
fin;

    inicia-ejecucion

    si junto-a-zumbador entonces apagate;
    orientarse;
    buscar_minotauro;

        apagate;
    termina-ejecucion
finalizar-programa
