iniciar-programa

    define-nueva-instruccion media-vuelta como inicio
        repetir 2 veces gira-izquierda;
    fin;

    define-nueva-instruccion regresa(k) como inicio
        si no si-es-cero(k) entonces inicio
            si frente-libre entonces inicio
                avanza;
                regresa(precede(k));
            fin sino inicio
                si izquierda-libre entonces inicio
                    gira-izquierda;
                    regresa(k);
                fin sino inicio
                    repetir 3 veces gira-izquierda;
                    regresa(k);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresaIzquierda(k) como inicio
        si no si-es-cero(k) entonces inicio
            si frente-libre entonces inicio
                avanza;
                regresaIzquierda(precede(k));
            fin sino inicio
                si frente-bloqueado y derecha-libre entonces inicio
                    repetir 3 veces gira-izquierda;
                    regresaIzquierda(k);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresaDerecha(k) como inicio
        si no si-es-cero(k) entonces inicio
            si frente-libre entonces inicio
                avanza;
                regresaDerecha(precede(k));
            fin sino inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    gira-izquierda;
                    regresaDerecha(k);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion camino como inicio
        si derecha-bloqueada y izquierda-bloqueada entonces inicio
            si frente-libre entonces inicio
                si no junto-a-zumbador entonces deja-zumbador;
                avanza;
                camino;
            fin;
        fin sino inicio
            si (izquierda-libre  o derecha-libre) y frente-bloqueado entonces inicio
                si izquierda-libre y frente-bloqueado entonces inicio
                    gira-izquierda;
                    si no junto-a-zumbador entonces deja-zumbador;
                    avanza;
                    camino;
                fin sino inicio
                    si derecha-libre y frente-bloqueado entonces inicio
                        repetir 3 veces gira-izquierda;
                        si no junto-a-zumbador entonces deja-zumbador;
                        avanza;
                        camino;
                    fin;
                fin;
            fin sino inicio
                si izquierda-libre y frente-libre entonces inicio
                    deja-zumbador;
                    gira-izquierda;
                    avanza;
                    si junto-a-zumbador entonces apagate;
                fin sino inicio
                    si derecha-libre y frente-libre entonces inicio
                        repetir 3 veces gira-izquierda;
                        deja-zumbador;
                        avanza;
                        si junto-a-zumbador entonces apagate;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion compara(k) como inicio
        repetir sucede(k) veces si junto-a-zumbador entonces inicio
            coge-zumbador;
        fin;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            media-vuelta;
        fin sino inicio
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion uno(n) como inicio
        si derecha-bloqueada y izquierda-bloqueada entonces inicio
            si frente-libre y derecha-bloqueada o izquierda-bloqueada entonces inicio
                avanza;
                uno(sucede(n));
            fin sino inicio
                si izquierda-libre entonces inicio
                    gira-izquierda;
                    uno(n);
                fin sino inicio
                    repetir 3 veces gira-izquierda;
                    uno(n);
                fin;
            fin;
        fin sino inicio
            si (izquierda-libre o derecha-libre) y frente-bloqueado entonces inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    gira-izquierda;
                    avanza;
                    uno(sucede(n));
                fin sino inicio
                    si frente-bloqueado y derecha-libre entonces inicio
                        repetir 3 veces gira-izquierda;
                        avanza;
                        uno(sucede(n));
                    fin;
                fin;
            fin sino inicio
                si izquierda-libre entonces inicio
                    media-vuelta;
                    regresa(n);
                    si junto-a-zumbador entonces inicio
                        compara(n);
                        si no junto-a-zumbador entonces deja-zumbador;
                        si frente-libre entonces avanza;
                        camino;
                    fin sino inicio
                        repetir sucede(n) veces deja-zumbador;
                        uno(0);
                    fin;
                fin sino inicio
                    si derecha-libre entonces inicio
                        media-vuelta;
                        regresa(n);
                        si junto-a-zumbador entonces inicio
                            compara(n);
                            si no junto-a-zumbador entonces deja-zumbador;
                            si frente-libre entonces avanza;
                            camino;
                        fin sino inicio
                            repetir sucede(n) veces deja-zumbador;
                            uno(0);
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion buscaDerecha(n) como inicio
        si derecha-bloqueada entonces inicio
            si frente-libre entonces inicio
                avanza;
                buscaDerecha(sucede(n));
            fin;
        fin sino inicio
            si frente-bloqueado y derecha-libre entonces inicio
                repetir 3 veces gira-izquierda;
                avanza;
                buscaDerecha(sucede(n));
            fin sino inicio
                si derecha-libre y frente-libre entonces inicio
                    media-vuelta;
                    regresaDerecha(n);
                    si junto-a-zumbador entonces inicio
                        compara(n);
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion buscaIzquierda(n) como inicio
        si izquierda-bloqueada entonces inicio
            si frente-libre entonces inicio
                avanza;
                buscaIzquierda(sucede(n));
            fin;
        fin sino inicio
            si frente-bloqueado y izquierda-libre entonces inicio
                gira-izquierda;
                avanza;
                buscaIzquierda(sucede(n));
            fin sino inicio
                si izquierda-libre y frente-libre entonces inicio
                    media-vuelta;
                    regresaIzquierda(n);
                    repetir sucede(n) veces deja-zumbador;
                    buscaDerecha(0);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion caminoIzquierdo como inicio
        si izquierda-bloqueada entonces inicio
            si frente-libre entonces inicio
                deja-zumbador;
                avanza;
                caminoIzquierdo;
            fin;
        fin sino inicio
            si izquierda-libre y frente-bloqueado entonces inicio
                gira-izquierda;
                deja-zumbador;
                avanza;
                caminoIzquierdo;
            fin sino inicio
                gira-izquierda;
                deja-zumbador;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion caminoDerecho como inicio
        si derecha-bloqueada entonces inicio
            si frente-libre entonces inicio
                deja-zumbador;
                avanza;
                caminoDerecho;
            fin;
        fin sino inicio
            si derecha-libre y frente-bloqueado entonces inicio
                repetir 3 veces gira-izquierda;
                deja-zumbador;
                avanza;
                caminoDerecho;
            fin sino inicio
                repetir 3 veces gira-izquierda;
                deja-zumbador;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        si frente-bloqueado y izquierda-libre y derecha-libre entonces inicio
            gira-izquierda;
        fin sino inicio
            si frente-libre y (derecha-libre o izquierda-libre) entonces inicio
                gira-izquierda;
                si frente-libre y (derecha-libre o izquierda-libre) entonces inicio
                    gira-izquierda;
                fin;
            fin;
        fin;
        uno(0);
        mientras no junto-a-zumbador hacer inicio
            repetir 3 veces gira-izquierda;
            buscaIzquierda(0);
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                caminoizquierdo;
            fin sino inicio
                caminoderecho;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
