iniciar-programa
define-nueva-instruccion gira(t) como
    repetir t veces gira-izquierda;
define-nueva-instruccion llena-camino(p) como inicio
    si si-es-cero(p) entonces inicio
        mientras no (frente-libre y izquierda-libre y no-junto-a-zumbador) hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            si frente-libre entonces inicio
                deja-zumbador;
                avanza;
            fin
            sino inicio
                gira(1);
                deja-zumbador;
            fin;
        fin;
        gira(1);
        si izquierda-bloqueada entonces inicio
            gira(3);
            deja-zumbador;
            avanza;
            llena-camino(p);
            sal-de-instruccion;
        fin;
    fin
    sino inicio
        mientras no (frente-libre y derecha-libre y no-junto-a-zumbador) hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            si frente-libre entonces inicio
                deja-zumbador;
                avanza;
            fin
            sino inicio
                gira(3);
                deja-zumbador;
            fin;
        fin;
        gira(3);
        si derecha-bloqueada entonces inicio
            gira(1);
            deja-zumbador;
            avanza;
            llena-camino(p);
            sal-de-instruccion;
        fin;
    fin;
fin;
define-nueva-instruccion sigue-camino(i) como inicio
    repetir i veces inicio
        si no junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                gira(3);
                avanza;
            fin;
        fin
        sino inicio
            sal-de-instruccion;
        fin;
    fin;
fin;
define-nueva-instruccion Busca-otro como inicio
    gira(1);
    avanza;
    gira(3);
    mientras no (frente-libre y izquierda-libre) hacer inicio
        si izquierda-bloqueada entonces inicio
            avanza;
            gira(3);
        fin
        sino inicio
            gira(1);
            avanza;
            gira(3);
        fin;
    fin;
fin;
define-nueva-instruccion Kareleseo(x) como inicio
    si frente-libre entonces inicio
        si izquierda-bloqueada entonces inicio
            avanza;
            gira(3);
            Kareleseo(sucede(x));
        fin
        sino inicio
            Busca-otro;
            gira(1);
            Sigue-camino(x);
            si junto-a-zumbador entonces inicio
                gira(2);
                coge-zumbador;
                llena-camino(0);
                deja-zumbador;
                avanza;
                si junto-a-zumbador entonces apagate;
                deja-zumbador;
                Kareleseo(0);
            fin
            sino inicio
                mientras no-junto-a-zumbador hacer inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin
                    sino inicio
                        gira(3);
                    fin;
                fin;
                coge-zumbador;
                llena-camino(1);
                deja-zumbador;
                avanza;
                si junto-a-zumbador entonces apagate;
                deja-zumbador;
                Kareleseo(0);
            fin;
        fin;
    fin
    sino inicio
        gira(1);
        avanza;
        gira(3);
        Kareleseo(sucede(x));
    fin;
fin;
    inicia-ejecucion
        mientras derecha-libre hacer gira(1);
        mientras frente-libre hacer inicio
            avanza;
            deja-zumbador;
        fin;
        si derecha-libre entonces inicio
            gira(2);
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                avanza;
            fin;
            gira(1);
        fin
        sino inicio
            gira(2);
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                avanza;
            fin;
            gira(3);
        fin;
        deja-zumbador;
        si izquierda-libre entonces inicio
            gira(1);
            avanza;
            gira(3);
            Kareleseo(1);
        fin
        sino inicio
            Kareleseo(0);
        fin;

        apagate;
    termina-ejecucion
finalizar-programa
