iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si derecha-libre entonces inicio
                gira(3);
                avanza;
            fin sino inicio
                gira(1);
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion menor(n) como inicio
        repetir n veces si junto-a-zumbador entonces coge-zumbador;
        si junto-a-zumbador entonces inicio
            gira(2);
            mientras junto-a-zumbador hacer coge-zumbador;
            mientras (izquierda-bloqueada o frente-bloqueado) hacer inicio
                deja-zumbador;
                paso;
            fin;
            deja-zumbador;
            gira(1);
            avanza;
            gira(1);
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            mientras (derecha-bloqueada o frente-bloqueado) hacer inicio
                deja-zumbador;
                paso;
            fin;
            deja-zumbador;
            gira(3);
            avanza;
            gira(1);
        fin;
    fin;

    define-nueva-instruccion menor_primer(n) como inicio
        repetir n veces si junto-a-zumbador entonces coge-zumbador;
        si junto-a-zumbador entonces gira(2);

        mientras junto-a-zumbador hacer coge-zumbador;
        deja-zumbador;
        paso;
        mientras ((derecha-bloqueada y izquierda-bloqueada) o frente-bloqueado) hacer inicio
            deja-zumbador;
            paso;
        fin;
        deja-zumbador;
        si derecha-libre entonces inicio
            gira(3);
        fin sino inicio
            gira(1);
        fin;
        avanza;
        gira(1);
    fin;

    define-nueva-instruccion cuenta2(n) como inicio
        si (izquierda-bloqueada o frente-bloqueado) entonces inicio
            paso;
            cuenta2(sucede(n));
        fin sino inicio
            gira(2);
            mientras no-junto-a-zumbador hacer paso;
            menor(n);
        fin;
    fin;

    define-nueva-instruccion cuenta1(n) como inicio
        si (derecha-bloqueada o frente-bloqueado) entonces inicio
            paso;
            cuenta1(sucede(n));
        fin sino inicio
            gira(2);
            mientras no-junto-a-zumbador hacer paso;
            coge-zumbador;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion cuenta_primer2(n) como inicio
        si ((izquierda-bloqueada y derecha-bloqueada) o frente-bloqueado) entonces inicio
            paso;
            cuenta_primer2(sucede(n));
        fin sino inicio
            gira(2);
            mientras no-junto-a-zumbador hacer paso;
            menor_primer(n);
        fin;
    fin;

    define-nueva-instruccion cuenta_primer(n) como inicio
        si ((izquierda-bloqueada y derecha-bloqueada) o frente-bloqueado) entonces inicio
            paso;
            cuenta_primer(sucede(n));
        fin sino inicio
            gira(2);
            mientras no-junto-a-zumbador hacer paso;
            coge-zumbador;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion circulo como inicio
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            cuenta1(1);
            cuenta2(1);
        fin;
    fin;

    define-nueva-instruccion primer como inicio
        mientras frente-libre hacer gira(1);
        deja-zumbador;
        cuenta_primer(1);
        cuenta_primer2(2);
    fin;

    inicia-ejecucion
        si no-junto-a-zumbador entonces primer;
        circulo;
        apagate;
    termina-ejecucion
finalizar-programa
