iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion deja-camino como inicio
    si frente-bloqueado y derecha-bloqueada entonces gira-izquierda;
    avanza;
    deja-zumbador;
    si frente-bloqueado entonces inicio
        gira-izquierda;
        si frente-bloqueado entonces gira(2);
        avanza;
        deja-zumbador;
    fin;
    si izquierda-bloqueada y derecha-bloqueada entonces deja-camino;
fin;

define-nueva-instruccion b(z) como inicio
    si no-junto-a-zumbador entonces inicio
        si frente-bloqueado entonces gira-izquierda;
        avanza;
        si si-es-cero(z) entonces b(z)
        sino b(precede(z));
    fin sino inicio
        si no si-es-cero(z) entonces gira(2);
    fin;
fin;

define-nueva-instruccion a(z) como inicio
    si izquierda-bloqueada o frente-bloqueado o junto-a-zumbador entonces inicio
        si frente-bloqueado entonces gira-izquierda;
        avanza;
        a(sucede(z))
    fin sino inicio
        avanza;
        mientras izquierda-bloqueada o frente-bloqueado hacer inicio
            si frente-bloqueado entonces gira-izquierda;
            avanza;
        fin;
        b(z);
    fin;
fin;

define-nueva-instruccion resuelve como inicio
    mientras derecha-libre hacer gira-izquierda;
    mientras no-junto-a-zumbador hacer inicio
        deja-zumbador;
        a(0);
        deja-camino;
        mientras frente-libre hacer avanza;
        si izquierda-bloqueada entonces inicio
            gira(2);
            avanza;
            mientras izquierda-bloqueada o no-junto-a-zumbador hacer avanza;
            gira-izquierda;
        fin sino inicio
            gira(2);
            avanza;
            mientras derecha-bloqueada o no-junto-a-zumbador hacer avanza;
            gira(3);
        fin;
        avanza;
        si frente-libre entonces inicio
            mientras frente-libre hacer inicio
                si izquierda-bloqueada o derecha-bloqueada entonces apagate;
                deja-zumbador;
                avanza;
            fin;
        fin;
        gira(3);
    fin;
fin;

    inicia-ejecucion
        deja-zumbador;
        si frente-bloqueado entonces gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(2);
        si izquierda-libre entonces inicio
            mientras no-junto-a-zumbador hacer avanza;
        fin sino inicio
            mientras no-junto-a-zumbador hacer avanza;
            gira(2);
        fin;
        coge-zumbador;
        resuelve;
        apagate;
    termina-ejecucion
finalizar-programa
