iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion acomoda como inicio
        deja-zumbador;
        sur;
        mientras frente-libre hacer
            avanza;
        si izquierda-bloqueada entonces inicio
            norte;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
        fin
        sino inicio
            si derecha-bloqueada entonces inicio
                norte;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                sur;
            fin
            sino inicio
                si izquierda-libre y derecha-libre entonces inicio
                    este;
                    mientras frente-libre hacer
                        avanza;
                    si izquierda-bloqueada entonces inicio
                        oeste;
                        mientras frente-libre y no-junto-a-zumbador hacer
                            avanza;
                    fin
                    sino inicio
                        oeste;
                        mientras frente-libre y no-junto-a-zumbador hacer
                            avanza;
                        este;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion lado1 (n) como inicio
        si izquierda-bloqueada entonces inicio
            avanza;
            deja-zumbador;
            lado1 (sucede(n));
        fin
        sino inicio
            si frente-bloqueado entonces inicio
                gira (1);
                avanza;
                deja-zumbador;
                lado1 (sucede(n));
            fin
            sino inicio
                gira (2);
                si frente-bloqueado y izquierda-bloqueada entonces inicio
                    gira (2);
                    avanza;
                    deja-zumbador;
                    lado1 (sucede(n));
                fin
                sino inicio
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                        si frente-libre entonces inicio
                            avanza;
                        fin
                        sino inicio
                            gira (3);
                            avanza;
                        fin;
                    fin;
                    gira (2);
                    si frente-libre entonces inicio
                        avanza;
                        gira (2);
                        repetir n veces
                            deja-zumbador;
                    fin
                    sino inicio
                        gira (1);
                        avanza;
                        gira (2);
                        repetir n veces
                            deja-zumbador;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion compara (n) como inicio
        si si-es-cero (n) entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara (precede(n));
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion lado2 (n) como inicio
        si derecha-bloqueada entonces inicio
            avanza;
            deja-zumbador;
            lado2 (sucede(n));
        fin
        sino inicio
            si frente-bloqueado entonces inicio
                gira (3);
                avanza;
                deja-zumbador;
                lado2 (sucede(n));
            fin
            sino inicio
                gira (2);
                si frente-bloqueado y derecha-bloqueada entonces inicio
                    gira (2);
                    avanza;
                    deja-zumbador;
                    lado2 (sucede(n));
                fin
                sino inicio
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                        si frente-libre entonces inicio
                            avanza;
                        fin
                        sino inicio
                            gira (1);
                            avanza;
                        fin;
                    fin;
                    gira (2);
                    si frente-libre entonces inicio
                        avanza;
                        deja-zumbador;
                        compara (n);
                        gira (2);
                    fin
                    sino inicio
                        gira (3);
                        avanza;
                        deja-zumbador;
                        compara (n);
                        gira (2);
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion next (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            next (sucede (n));
        fin
        sino inicio
            deja-zumbador;
            repetir n veces inicio
                si frente-libre entonces inicio
                    avanza;
                    deja-zumbador;
                fin
                sino inicio
                    gira (1);
                    avanza;
                    deja-zumbador;
                fin;
            fin;
            si izquierda-libre y frente-libre entonces inicio
                mientras izquierda-libre hacer inicio
                    gira (1);
                    avanza;
                    gira (3);
                    si junto-a-zumbador entonces inicio
                        apagate;
                    fin
                    sino inicio
                        deja-zumbador;
                    fin;
                fin;
            fin
            sino inicio
                gira (2);
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                    fin
                    sino inicio
                        gira (3);
                        avanza;
                    fin;
                fin;
                gira (2);
                si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    gira (1);
                    avanza;
                fin;
                gira (2);
                deja-zumbador;
                repetir n veces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin
                    sino inicio
                        gira (3);
                        avanza;
                    fin;
                    deja-zumbador;
                fin;
                si derecha-libre entonces inicio
                    gira (2);
                    mientras izquierda-libre hacer inicio
                        gira (1);
                        avanza;
                        gira (3);
                        si junto-a-zumbador entonces inicio
                            apagate;
                        fin
                        sino inicio
                            deja-zumbador;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion minotauro como inicio
        lado1 (0);
        lado2 (0);
        next (0);
        minotauro;
    fin;
    define-nueva-instruccion kareleseo como inicio
        acomoda;
        minotauro;
    fin;
    inicia-ejecucion
        kareleseo;
        apagate;
    termina-ejecucion
finalizar-programa