iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion Intercambia como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            Intercambia;
            deja-zumbador;
        fin
        sino inicio
            gira(2);
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion TomaMayor(z) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            TomaMayor(sucede(z));
            si junto-a-zumbador entonces coge-zumbador;
        fin
        sino inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            si frente-libre entonces avanza
            sino inicio
                gira(2);
                sal-de-instruccion;
            fin;
        fin;
    fin;
    define-nueva-instruccion ordena como inicio
        mientras orientado-al-norte hacer inicio
            TomaMayor(0);
            si orientado-al-sur o junto-a-zumbador entonces mientras algun-zumbador-en-la-mochila hacer deja-zumbador
            sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                Intercambia;
                gira(2);avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion CreaPanorama como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        ordena;
        mientras junto-a-zumbador hacer coge-zumbador;
        mientras frente-libre hacer inicio
           (* mientras junto-a-zumbador hacer coge-zumbador;______ERROR.1*)
            avanza;
        fin;
        gira(2);
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;
    inicia-ejecucion
        mientras orientado-al-norte hacer inicio
            CreaPanorama;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            si frente-libre entonces avanza
            sino apagate;
            gira(1);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
