iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion formar como
    inicio
        mientras frente-libre y no-junto-a-zumbador hacer
        inicio
             mientras frente-libre y no-junto-a-zumbador hacer avanza;
             si junto-a-zumbador entonces
             inicio
                 mientras junto-a-zumbador hacer coge-zumbador;
                 sur;
                 mientras frente-libre hacer avanza;
                 norte;
                 mientras algun-zumbador-en-la-mochila hacer
                 inicio
                     deja-zumbador;
                     avanza;
                 fin;
                 mientras junto-a-zumbador hacer avanza;
             fin;
        fin;
        sur;
        mientras frente-libre hacer avanza;
        este;
        si frente-libre entonces
        inicio
            avanza;
            norte;
        fin;
   fin;

   define-nueva-instruccion quitar como
   inicio
       mientras frente-libre hacer
       inicio
           mientras junto-a-zumbador hacer
           inicio
               mientras junto-a-zumbador hacer coge-zumbador;
               deja-zumbador;
               avanza;
           fin;
           sur;
           mientras frente-libre hacer avanza;
           oeste;
           si frente-libre entonces
           inicio
               avanza;
               norte;
           fin;
       fin;
   fin;


    inicia-ejecucion
        mientras frente-libre hacer formar;
        norte;
        quitar;
        apagate;
    termina-ejecucion
finalizar-programa
