iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion dibuja como
        inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            sur;
            mientras frente-libre hacer avanza;
            norte;
            mientras algun-zumbador-en-la-mochila hacer
                inicio
                    deja-zumbador;
                    avanza;
                fin;
            mientras junto-a-zumbador hacer avanza;
        fin;

    define-nueva-instruccion ciudad como
        inicio
            mientras orientado-al-norte hacer
                inicio
                    mientras no-junto-a-zumbador y frente-libre hacer avanza;
                    si junto-a-zumbador entonces dibuja;
                    si no-junto-a-zumbador y frente-bloqueado entonces
                        inicio
                            si derecha-libre entonces
                                inicio
                                    este;
                                    avanza;
                                    sur;
                                    mientras frente-libre hacer avanza;
                                    norte;
                                fin
                            sino sur;
                        fin;
                fin;
        fin;

    define-nueva-instruccion junta como
        inicio
            mientras frente-libre hacer avanza;
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            mientras orientado-al-norte hacer
                inicio
                    mientras junto-a-zumbador hacer
                        inicio
                            mientras junto-a-zumbador hacer coge-zumbador;
                            deja-zumbador;
                            avanza;
                        fin;
                    si derecha-libre entonces
                        inicio
                            este;
                            avanza;
                            sur;
                            mientras frente-libre hacer avanza;
                            norte;
                        fin
                    sino sur;
                fin;
        fin;

    inicia-ejecucion
        ciudad;
        junta;
        apagate;
    termina-ejecucion
finalizar-programa
