iniciar-programa
    define-nueva-instruccion revisa como inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si junto-a-zumbador entonces coge-zumbador;
        si frente-libre entonces avanza;
    fin;
    define-nueva-instruccion revisaa como si junto-a-zumbador entonces coge-zumbador;
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion poda como inicio
        mientras frente-libre hacer inicio
            revisaa;
            avanza;
        fin;
        revisaa;
    fin;
    define-nueva-instruccion vuelve como inicio
        gira(2);
        mientras frente-libre hacer avanza;
        si algun-zumbador-en-la-mochila entonces deja-zumbador;
        gira(2);
        si frente-libre entonces avanza;
        si algun-zumbador-en-la-mochila entonces inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin;
        si frente-libre entonces avanza;
    fin;
    define-nueva-instruccion acomoda como inicio
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;
    define-nueva-instruccion columna como inicio
        poda;
        mientras algun-zumbador-en-la-mochila hacer inicio
            vuelve;
            poda;
        fin;
        vuelve;
        acomoda;
    fin;
    define-nueva-instruccion expande como inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
            avanza;
        fin;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;
    inicia-ejecucion
        mientras derecha-libre hacer inicio
            columna;
            gira(3);
            avanza;
            gira-izquierda;
        fin;
        columna;
        mientras izquierda-libre hacer inicio
            expande;
            gira-izquierda;
            avanza;
            gira(3);
        fin;
        expande;
        apagate;
    termina-ejecucion
finalizar-programa
