iniciar-programa
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur  como
    mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;

define-nueva-instruccion regresar como inicio
    sur;
    mientras frente-libre hacer avanza;
    norte;
    mientras algun-zumbador-en-la-mochila hacer inicio
        deja-zumbador;
        avanza;
    fin;
fin;
define-nueva-instruccion barrer como inicio
    mientras junto-a-zumbador hacer inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        deja-zumbador;
        avanza;
    fin;
    norte;
    mientras frente-libre hacer avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    sur;
    mientras frente-libre hacer avanza;
fin;
define-nueva-instruccion cruzar como inicio
    sur;
    si izquierda-libre entonces inicio
        este;
        avanza;
        norte;
    fin;
fin;
define-nueva-instruccion  coger como inicio
    mientras frente-libre y no junto-a-zumbador hacer avanza;
    mientras junto-a-zumbador hacer coge-zumbador;
    si algun-zumbador-en-la-mochila entonces inicio
        regresar;
    fin sino inicio
        regresar;
        barrer;
        cruzar;
    fin;
    si ningun-zumbador-en-la-mochila y derecha-libre entonces inicio
        si frente-bloqueado entonces inicio
            regresar;
            cruzar;
        fin;
    fin;
fin;
define-nueva-instruccion escombro como inicio
    norte;
    mientras frente-libre hacer avanza;
    gira-izquierda;
    mientras frente-libre hacer inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        avanza;
    fin;
    mientras junto-a-zumbador hacer coge-zumbador;
fin;
    inicia-ejecucion
        mientras frente-libre hacer inicio
            coger;
            mientras junto-a-zumbador y orientado-al-norte hacer avanza;
        fin;
        escombro;

        apagate;
    termina-ejecucion
finalizar-programa
 