iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion cambia-renglon como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            norte;
        fin sino inicio
            apagate;
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
        fin;
        repetir n veces inicio
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion toma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            toma(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                mientras no-junto-a-zumbador y frente-libre hacer inicio
                    avanza;
                fin;
                si junto-a-zumbador entonces inicio
                    compara(n)
                fin sino inicio
                    sur;
                    mientras frente-libre hacer avanza;
                    norte;
                    repetir n veces inicio
                        deja-zumbador;
                        si frente-libre entonces inicio
                            avanza;
                        fin;
                    fin;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                fin;
            fin sino inicio
                sur;
                mientras frente-libre hacer avanza;
                norte;
                repetir n veces inicio
                    deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                    fin;
                fin;
                mientras frente-libre hacer inicio
                        avanza;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
    mientras no-orientado-al-oeste hacer inicio
        mientras no-junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        mientras frente-libre hacer inicio
            toma(0);
        fin;
        si frente-bloqueado entonces toma(0);
        cambia-renglon;
    fin;
    termina-ejecucion
finalizar-programa
