iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion compara(n) como inicio
        si no si-es-cero(n) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara(precede(n));
                deja-zumbador;
            fin;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                norte;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzar como inicio
        norte;
        si frente-libre entonces avanza;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si frente-bloqueado y no junto-a-zumbador entonces inicio
            sur;
            mientras frente-libre hacer avanza;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin sino inicio
                oeste;
                mientras frente-libre hacer avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion edificio(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            edificio(sucede(n));
        fin sino inicio
            sur;
            mientras frente-libre hacer avanza;
            compara(n);
            si orientado-al-sur entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion construye como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            construye;
            deja-zumbador;
            si frente-libre entonces avanza;
        fin sino inicio
            norte;
        fin;
    fin;

    inicia-ejecucion
        si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces apagate;
        mientras no orientado-al-oeste hacer inicio
            avanzar;
            si no orientado-al-oeste entonces inicio
                edificio(0);
            fin;
        fin;
        norte;
        mientras no orientado-al-oeste hacer inicio
            construye;
            sur;
            mientras frente-libre hacer avanza;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
