iniciar-programa
define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
define-nueva-instruccion dibuja como
inicio
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces
    inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
            avanza;
        fin;
        mientras junto-a-zumbador hacer avanza;
        dibuja;
    fin
    sino
    inicio
        gira(2);
        mientras frente-libre hacer avanza;
        gira(1);
        si frente-libre entonces
        inicio
            avanza;
            gira(1);
            dibuja;
        fin;
    fin;
fin;
define-nueva-instruccion borra como
inicio
    mientras junto-a-zumbador hacer
    inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        deja-zumbador;
        avanza;
    fin;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(1);
    si frente-libre entonces
    inicio
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        gira(1);
        si junto-a-zumbador entonces borra;
    fin;
fin;
    inicia-ejecucion
    dibuja;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(3);
    borra;
        apagate;
    termina-ejecucion
finalizar-programa
