iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion compara(x) como inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            repetir x veces inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
                fin;
            fin
            sino inicio
            mientras frente-libre hacer inicio
                si junto-a-zumbador entonces coge-zumbador;
                si frente-libre entonces avanza;
                fin;
            si junto-a-zumbador y frente-bloqueado entonces coge-zumbador;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            compara(sucede(x));
            fin;
        fin;
    inicia-ejecucion
        mientras derecha-libre hacer inicio
            compara(0);
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            gira(1);
            fin;
        compara(0);
        apagate;
    termina-ejecucion
finalizar-programa
