iniciar-programa
    define-nueva-instruccion hastapared como inicio
        mientras frente-libre hacer avanza;
    fin;

    define-nueva-instruccion hastabeeper como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;

    define-nueva-instruccion sinbeeper como inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
    fin;

    define-nueva-instruccion skylinea como inicio
        si junto-a-zumbador y orientado-al-sur entonces inicio
            coge-zumbador;
            skylinea;
            skylinea;
        fin sino inicio
            si orientado-al-sur entonces inicio
                hastapared;
                repetir 2 veces gira-izquierda;
            fin sino inicio
                si no-junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                fin;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion linea como inicio
        sinbeeper;
        hastabeeper;
        si junto-a-zumbador entonces inicio
            repetir 2 veces gira-izquierda;
            skylinea;
        fin sino inicio
            repetir 3 veces gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                repetir 3 veces gira-izquierda;
                hastapared;
                repetir 2 veces gira-izquierda;
            fin sino inicio
                sal-de-instruccion;
            fin;
        fin;
        linea;
     fin;
    inicia-ejecucion
    linea;
        apagate;
    termina-ejecucion
finalizar-programa
