iniciar-programa
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion numeros(n) como inicio
        si junto-a-zumbador y orientado-al-este entonces inicio
            coge-zumbador;
            numeros(sucede(n));
        fin sino inicio
            si orientado-al-este entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    numeros(0);
                fin sino inicio
                    oeste;
                    mientras frente-libre hacer avanza;
                    norte;
                    avanza;
                    si junto-a-zumbador entonces inicio
                        este;
                        numeros(0);
                    fin sino inicio
                        sur;
                        mientras frente-libre hacer avanza;
                        oeste;
                    fin;
                fin;
            fin;
            si orientado-al-oeste entonces inicio
                este;
                repetir precede(n) veces avanza;
                deja-zumbador;
                oeste;
                mientras frente-libre hacer avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta2(n) como inicio
        si frente-libre y orientado-al-oeste entonces inicio
            avanza;
            cuenta2(sucede(n));
        fin sino inicio
            este;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si frente-libre y orientado-al-oeste entonces inicio
            avanza;
            cuenta(sucede(n));
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
            deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
    este;
    numeros(0);
    este;
    mientras no-junto-a-zumbador hacer avanza;
    oeste;
    cuenta2(0);
    este;
    mientras frente-libre hacer avanza;
    oeste;
    mientras no-junto-a-zumbador hacer avanza;
    cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
