iniciar-programa
    define-nueva-instruccion gira(n) como inicio
       repetir n veces
          gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer
          gira(1);
    fin;
    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer
          gira(1);
    fin;
    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer
          gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer
          gira(1);
    fin;
    define-nueva-instruccion compara(n) como inicio
       si junto-a-zumbador y no (si-es-cero(n)) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
       fin
       sino inicio
          si junto-a-zumbador y si-es-cero(n) entonces inicio
             norte;
          fin
          sino inicio
             si no-junto-a-zumbador y no si-es-cero(n) entonces inicio
                sur;
             fin;
          fin;
       fin;
    fin;
    define-nueva-instruccion termina como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          termina;
          deja-zumbador;
       fin
       sino inicio
          sur;
          mientras frente-libre hacer
             avanza;
          mientras junto-a-zumbador hacer
             coge-zumbador;
       fin;
    fin;
    define-nueva-instruccion cuentamin(n) como inicio
       si orientado-al-sur entonces inicio
          si junto-a-zumbador entonces inicio
             coge-zumbador;
             cuentamin(sucede(n));
          fin
          sino inicio
             repetir n veces
                deja-zumbador;
             este;
             cuentamin(n);
          fin;
       fin
       sino inicio
          si junto-a-zumbador entonces inicio
             compara(n);
             si orientado-al-sur entonces inicio
                cuentamin(0);
             fin
             sino inicio
                este;
                avanza;
                cuentamin(n);
             fin;
          fin
          sino inicio
             norte;
             avanza;
             oeste;
             mientras frente-libre hacer
                avanza;
             este;
             si no-junto-a-zumbador entonces inicio
                sur;
                mientras frente-libre hacer
                   avanza;
                este;
                avanza;
                mientras junto-a-zumbador hacer
                   coge-zumbador;
                repetir n veces
                   deja-zumbador;
                oeste;
                avanza;
                norte;
                mientras frente-libre hacer
                   avanza;
                termina;
             fin
             sino inicio
                cuentamin(n);
             fin;
          fin;
       fin;
    fin;
    define-nueva-instruccion cuentamax(n) como inicio
       si orientado-al-norte entonces inicio
          si junto-a-zumbador entonces inicio
             coge-zumbador;
             cuentamax(sucede(n));
          fin
          sino inicio
             repetir n veces
                deja-zumbador;
             este;
             cuentamax(n);
          fin;
       fin
       sino inicio
          si junto-a-zumbador entonces inicio
             compara(n);
             si orientado-al-norte entonces inicio
                cuentamax(0);
             fin
             sino inicio
                este;
                avanza;
                cuentamax(n);
             fin;
          fin
          sino inicio
             norte;
             avanza;
             oeste;
             mientras frente-libre hacer
                avanza;
             este;
             si no-junto-a-zumbador entonces inicio
                norte;
                mientras frente-libre hacer
                   avanza;
                repetir n veces
                   deja-zumbador;
                sur;
                mientras frente-libre hacer
                   avanza;
                este;
             fin
             sino inicio
                cuentamax(n);
             fin;
          fin;
       fin;
    fin;
    inicia-ejecucion
        este;
        cuentamax(0);
        cuentamin(101);
        apagate;
    termina-ejecucion
finalizar-programa