iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        avanza;
        este;
    fin;


    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar(sucede(n));
        fin sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                juntar(0);
            fin sino inicio
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
                avanza;
                norte;
            fin;
            si junto-a-zumbador y orientado-al-norte entonces inicio
                juntar(0);
            fin;
            ir11;
            repetir precede(n) veces inicio
                avanza;
            fin;
            si no junto-a-zumbador  entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion dejar como inicio
         sur;
         avanza;
         oeste;
         mientras frente-libre hacer inicio
             avanza;
        fin;
    fin;


    define-nueva-instruccion tomar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(sucede(n));
        fin sino inicio
            si orientado-al-oeste entonces inicio
                dejar;
            fin sino inicio
                dejar;
                este;
                avanza;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
    juntar(0);
    mientras frente-libre hacer inicio
        avanza;
    fin;
    oeste;
    mientras no junto-a-zumbador y frente-libre hacer inicio
        avanza;
    fin;
    tomar(0);
    norte;
    avanza;
    este;
    mientras no junto-a-zumbador y frente-libre hacer inicio
        avanza;
    fin;
    tomar(0);


        apagate;
    termina-ejecucion
finalizar-programa
