iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion mayor(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(x));
        fin sino inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                repetir x veces inicio
                    si junto-a-zumbador entonces coge-zumbador;
                fin;
                mayor(x);
            fin sino inicio
                repetir x veces deja-zumbador;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion menor(x) como inicio
        mientras junto-a-zumbador y frente-libre hacer inicio
            coge-zumbador;
            avanza;
        fin;
        oeste;
        si no-junto-a-zumbador entonces avanza;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            este;
            menor(sucede(x));
        fin sino inicio
            este;
            si frente-libre entonces avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            oeste;
            mayor(0);
            repetir x veces deja-zumbador;
            avanza;
            repetir x veces deja-zumbador;
            oeste;
            avanza;
            norte;
            avanza;
            este;
        fin;
    fin;                                       

    define-nueva-instruccion minimo(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                mientras frente-libre hacer avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir x veces deja-zumbador;
                apagate;
            fin;
            si frente-libre entonces inicio
                avanza;
                minimo(x);
            fin sino inicio
                norte;
                mientras junto-a-zumbador y frente-libre hacer avanza;
                sur;
                si no-junto-a-zumbador entonces avanza;
                minimo(sucede(x));
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras junto-a-zumbador y orientado-al-este hacer inicio
            menor(1);
        fin;
        sur;
        mayor(0);
        avanza;
        norte;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        sur;
        si no-junto-a-zumbador entonces avanza;
        minimo(1);
        apagate;
    termina-ejecucion
finalizar-programa
