iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion sube (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sube (sucede(n));
        fin
        sino inicio
            avanza;
            mientras junto-a-zumbador hacer
                avanza;
            repetir n veces
                deja-zumbador;
            sur;
            mientras frente-libre hacer
                avanza;
            este;
            avanza;
            norte;
            si junto-a-zumbador entonces inicio
                sube (0);
            fin
            sino inicio
                oeste;
                mientras frente-libre hacer
                    avanza;
                norte;
                avanza;
                este;
                mientras junto-a-zumbador hacer
                    avanza;
                oeste;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        este;
    fin;
    define-nueva-instruccion acomoda (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomoda (sucede(n));
        fin
        sino inicio
            orienta;
            repetir precede (n) veces
                avanza;
            deja-zumbador;
            oeste;
            mientras frente-libre hacer
                avanza;
            norte;
            avanza;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si junto-a-zumbador entonces inicio
                este;
                mientras junto-a-zumbador hacer
                    avanza;
                oeste;
                avanza;
            fin
            sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion ordena como inicio
        si junto-a-zumbador entonces inicio
            acomoda (0);
            ordena;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                ordena;
            fin
            sino inicio
                si derecha-libre entonces inicio
                    norte;
                    avanza;
                    si junto-a-zumbador entonces inicio
                        este;
                        mientras junto-a-zumbador hacer
                            avanza;
                        oeste;
                        avanza;
                        ordena;
                    fin
                    sino inicio
                        orienta;
                    fin;
                fin
                sino inicio
                    orienta;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion menor (n) como inicio
        si no-junto-a-zumbador y frente-libre entonces inicio
            avanza;
            menor (sucede(n));
        fin
        sino inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            oeste;
            mientras frente-libre hacer
                avanza;
            norte;
            avanza;
            este;
            avanza;
            repetir sucede (n) veces
                deja-zumbador;
            orienta;
        fin;
    fin;
    define-nueva-instruccion mayor (n) como inicio
        si frente-libre y no-junto-a-zumbador entonces inicio
            avanza;
            mayor (sucede(n));
        fin
        sino inicio
            mientras frente-libre hacer inicio
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                avanza;
            fin;
            repetir 100 veces
                deja-zumbador;
            repetir n veces
                coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion otro (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            otro (sucede(n));
        fin
        sino inicio
            sur;
            avanza;
            repetir n veces
                deja-zumbador;
            oeste;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion aluxes como inicio
        norte;
        sube (0);
        ordena;
        menor (0);
        mientras frente-libre hacer
            avanza;
        oeste;
        mayor (0);
        norte;
        avanza;
        este;
        avanza;
        otro (0);
    fin;
    inicia-ejecucion
        aluxes;
        apagate;
    termina-ejecucion
finalizar-programa