iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion buscasum como
  inicio
    mientras no orientado-al-norte y  no junto-a-zumbador hacer
      inicio
        si frente-libre entonces avanza
        sino
          inicio
            sur;
            si frente-libre entonces
              inicio
                avanza;
                si izquierda-bloqueada entonces oeste sino este;
              fin
            sino norte;
          fin;
      fin;
  fin;

define-nueva-instruccion irnuevo como
  inicio
    norte;
    mientras frente-libre hacer avanza;
    este;
    mientras frente-libre hacer avanza;
    sur;
    mientras izquierda-bloqueada hacer avanza;
    este;
    avanza;
    mientras izquierda-bloqueada hacer avanza;
    norte;
    avanza;
    mientras izquierda-bloqueada hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
  fin;

define-nueva-instruccion irviejo como
  inicio
    norte;
    mientras frente-libre hacer avanza;
    este;
    mientras izquierda-bloqueada hacer avanza;
    sur;
    avanza;
    mientras derecha-bloqueada hacer avanza;
    oeste;
    avanza;
    mientras derecha-bloqueada hacer avanza;
    norte;
    avanza;
    mientras izquierda-bloqueada hacer avanza;
    oeste;
    avanza;
  fin;


define-nueva-instruccion contar2(n) como
  inicio
    si frente-libre entonces
      inicio
        avanza;
        contar2 (sucede(sucede(n)));
      fin
    sino
      inicio
        irnuevo;
        repetir n veces avanza;
        sur;
      fin;
  fin;

define-nueva-instruccion contar1(n) como
  inicio
    si frente-libre entonces
      inicio
        avanza;
        contar1(sucede(sucede(n)));
      fin
    sino
      inicio
        oeste;
        contar2(0);
        repetir n veces avanza;
      fin;
  fin;

define-nueva-instruccion pinta como
  inicio
    deja-zumbador;
    este;
    avanza;
    deja-zumbador;
    sur;
    avanza;
    deja-zumbador;
    oeste;
    avanza;
    deja-zumbador;
  fin;
    inicia-ejecucion
         oeste;
         buscasum;
         mientras junto-a-zumbador hacer
           inicio
            coge-zumbador;
            norte;
            contar1(0);
            pinta;
            irviejo;
            buscasum;
           fin;
        apagate;
    termina-ejecucion
finalizar-programa
