iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ve-salon2 como inicio
        norte;
        mientras derecha-bloqueada hacer avanza;
        este;
        avanza;
        norte;
        mientras derecha-bloqueada y frente-libre hacer avanza;
        si frente-bloqueado entonces inicio
            repetir 2 veces gira-izquierda;
            repetir 2 veces inicio
                mientras izquierda-bloqueada hacer avanza;
                gira-izquierda;
                avanza;
            fin;
            mientras izquierda-bloqueada hacer avanza;
        fin sino inicio
            repetir 3 veces gira-izquierda;
            avanza;
            mientras derecha-bloqueada hacer avanza;
            repetir 3 veces gira-izquierda;
            avanza;
        fin;
        oeste;
        avanza;
        sur;
    fin;
    define-nueva-instruccion cambia como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            sur;
            corre;
            este;
            si frente-libre  entonces inicio
                avanza;
                si derecha-libre entonces inicio
                    oeste;
                    avanza;
                fin sino norte;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion aumenta como inicio
        si no-orientado-al-oeste entonces inicio
            si junto-a-zumbador entonces inicio
                cambia;
                aumenta;
                avanza;
                repetir 4 veces inicio
                    deja-zumbador;
                    repetir 3 veces gira-izquierda;
                    avanza;
                fin;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    oeste;
                    repetir 2 veces si frente-libre entonces avanza;
                    norte;
                    corre;
                    sur;
                fin;
            fin sino inicio
                cambia;
                aumenta;
                repetir 2 veces si frente-libre entonces inicio
                    avanza;
                fin;
                si frente-bloqueado entonces inicio
                    oeste;
                    repetir 2 veces si frente-libre entonces avanza;
                    norte;
                    corre;
                    sur;
                fin;
            fin;
        fin sino inicio
            ve-salon2;
        fin;
    fin;
    inicia-ejecucion
        oeste;
        corre;
        sur;
        corre;
        norte;
        aumenta;
        apagate;
    termina-ejecucion
finalizar-programa
