iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion esquina-inferior como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;
    define-nueva-instruccion buscar como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        si orientado-al-oeste y derecha-bloqueada entonces esquina-inferior;
        mientras no-orientado-al-este y no-junto-a-zumbador hacer inicio
            si frente-libre y no-junto-a-zumbador entonces avanza;
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    si frente-bloqueado y derecha-libre y no-junto-a-zumbador entonces apagate;
                    gira(1);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion esquina-derecha como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        si derecha-bloqueada y izquierda-bloqueada entonces inicio
            sal-de-instruccion;
        fin sino inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(1);
            mientras derecha-bloqueada hacer avanza;
        fin;
    fin;
    define-nueva-instruccion nuevo-mural como inicio
        esquina-derecha;
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras derecha-bloqueada hacer avanza;
        gira(3);
        avanza;
        mientras derecha-bloqueada hacer avanza;
        gira(3);
        avanza;
        gira(3);
        avanza;
        esquina-inferior;
    fin;
    define-nueva-instruccion arriba(n) como inicio
        si frente-libre entonces inicio
            avanza;
            arriba(sucede(n));
        fin;
        si frente-bloqueado y orientado-al-sur entonces inicio
            nuevo-mural;
            repetir n veces inicio
                repetir 2 veces avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion izquierda(n) como inicio
       si orientado-al-oeste y frente-libre entonces inicio
           avanza;
           izquierda(sucede(n));
       fin;
       si frente-bloqueado entonces inicio
           gira(1);
           arriba(0);
           gira(3);
           repetir n veces inicio
               repetir 2 veces avanza;
           fin;
       fin;
    fin;
    define-nueva-instruccion viejo-mural como inicio
        gira(3);
        avanza;
        gira(1);
        avanza;
        gira(1);
        avanza;
        mientras izquierda-bloqueada hacer avanza;
        avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        avanza;
        gira(3);
        avanza;
    fin;
    define-nueva-instruccion duplicar como inicio
        repetir 4 veces inicio
            deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                gira(1);
            fin;
        fin;
    fin;
inicia-ejecucion
    mientras frente-libre o junto-a-zumbador hacer inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        buscar;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            gira(1);
            izquierda(0);
            duplicar;
            esquina-derecha;
            viejo-mural;
        fin;
        mientras no-orientado-al-sur hacer gira-izquierda;
        si frente-bloqueado y derecha-libre y izquierda-libre entonces gira(3);
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
