iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion rodea como inicio
        norte;
        mientras derecha-bloqueada hacer
            avanza;
        este;
        avanza;
        mientras derecha-bloqueada hacer
            avanza;
        sur;
        avanza;
        oeste;
        avanza;
        sur;
    fin;
    define-nueva-instruccion escala como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            escala;
            deja-zumbador;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                escala;
                avanza;
                avanza;
            fin
            sino inicio
                si derecha-libre entonces inicio
                    este;
                    avanza;
                    si frente-libre entonces inicio
                        sur;
                        mientras frente-libre hacer
                            avanza;
                        norte;
                        escala;
                        oeste;
                        avanza;
                        avanza;
                        norte;
                        mientras frente-libre hacer
                            avanza;
                        sur;
                    fin
                    sino inicio
                        rodea;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuatro (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuatro (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            sur;
            avanza;
            repetir n veces
                deja-zumbador;
            oeste;
            avanza;
            repetir n veces
                deja-zumbador;
            norte;
            avanza;
            repetir n veces
                deja-zumbador;
            este;
            avanza;
            norte;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                sur;
                mientras frente-libre hacer
                    avanza;
                oeste;
                avanza;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                fin
                sino inicio
                    apagate;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion amplia como inicio
        si junto-a-zumbador entonces inicio
            cuatro (0);
            amplia;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                amplia;
            fin
            sino inicio
                si izquierda-libre entonces inicio
                    oeste;
                    avanza;
                    si frente-libre entonces inicio
                        avanza;
                        sur;
                        mientras frente-libre hacer
                            avanza;
                        norte;
                        amplia;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion mural como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
        escala;
        sur;
        mientras frente-libre hacer
            avanza;
        este;
        mientras frente-libre hacer
            avanza;
        norte;
        amplia;
    fin;
    inicia-ejecucion
        mural;
        apagate;
    termina-ejecucion
finalizar-programa