iniciar-programa
                   
define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion bajar(b) como inicio
    gira(b);
    avanza;
    gira(b);
fin;

define-nueva-instruccion transladarse(c) como inicio
    mientras no-orientado-al-norte hacer gira(1);
    mientras frente-libre hacer avanza;
    gira(3);
    mientras frente-libre hacer avanza;
    gira(1);
    mientras derecha-bloqueada hacer avanza;
    gira(3);
    avanza;
    mientras derecha-bloqueada hacer avanza;
    bajar(3);
    avanza;
    gira(1);
    mientras frente-libre hacer avanza;
    gira(3);
    si si-es-cero(precede(c)) entonces inicio
        mientras frente-libre hacer avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion dibujar(d) como inicio
    deja-zumbador;
    gira(d);
    avanza;
    deja-zumbador;
    repetir 2 veces inicio
        gira(sucede(sucede(d)));
        avanza;
        deja-zumbador;
    fin;
    gira(d);
fin;

define-nueva-instruccion descender(e) como inicio
    gira(e);
    repetir 2 veces si frente-libre entonces avanza;
    gira(e);
fin;

define-nueva-instruccion recordar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        recordar(sucede(a));
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            recordar(0);
        fin sino inicio
            deja-zumbador;
            si orientado-al-oeste y izquierda-libre entonces inicio
                bajar(1);
                recordar(0);
            fin sino si orientado-al-este y derecha-libre entonces inicio
                bajar(3);
                recordar(0);
            fin;
        fin;
        si (frente-bloqueado y orientado-al-oeste y izquierda-bloqueada y junto-a-zumbador)
         o (frente-bloqueado y orientado-al-este y derecha-bloqueada y junto-a-zumbador) entonces inicio
            si orientado-al-oeste entonces inicio
                transladarse(1);
            fin sino transladarse(0);
        fin;
        si si-es-cero(precede(a)) entonces inicio
            si orientado-al-oeste entonces inicio
                dibujar(3);
            fin sino inicio
                dibujar(1);
            fin;
        fin sino avanza;
        si frente-bloqueado entonces inicio
            si orientado-al-oeste entonces inicio
                descender(3);
            fin sino descender(1);
        fin sino avanza;
    fin;
fin;

    inicia-ejecucion

    mientras no-orientado-al-oeste hacer gira(1);
    recordar(0);

        apagate;
    termina-ejecucion
finalizar-programa
