iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion salta como inicio
        si orientado-al-este entonces inicio
            gira(1);
            mientras derecha-bloqueada y frente-libre hacer avanza;
            si derecha-libre entonces inicio
                gira(3);
                avanza;
                gira(3);
                mientras frente-libre hacer avanza;
                gira(1);
            fin
            sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
            fin;
        fin
        sino inicio
            gira(3);
            mientras izquierda-bloqueada y frente-libre hacer avanza;
            gira(1);
            avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(3);
        fin;
    fin;
    define-nueva-instruccion media como inicio
        si orientado-al-este entonces inicio
            si frente-libre entonces avanza sino salta;
            si frente-libre y orientado-al-este entonces avanza
                sino si orientado-al-este entonces salta;
            si orientado-al-este entonces inicio
                media;
                mientras no orientado-al-oeste hacer gira(1);
                si frente-libre entonces avanza sino salta;
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer gira(1);
        media;
        apagate;
    termina-ejecucion
finalizar-programa
