iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    repetir 3 veces gira-izquierda;
fin;
define-nueva-instruccion cruzar-pared como
inicio
    gira-izquierda;
    mientras derecha-bloqueada y frente-libre hacer avanza;
    gira-derecha;
    si frente-libre entonces
    inicio
        avanza;
        gira-derecha;
        avanza;
        mientras frente-libre hacer avanza;
        gira-izquierda;
    fin;
    si frente-bloqueado entonces
    inicio
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        si frente-bloqueado entonces
        inicio
            gira-derecha;
            avanza;
            si izquierda-libre entonces
            inicio
                mientras frente-libre hacer avanza;
                gira-izquierda;
            fin
            sino inicio
                gira-izquierda;
                gira-izquierda;
                avanza;
                gira-derecha;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion cruzar-dos como
inicio
    gira-derecha;
    mientras izquierda-bloqueada y frente-libre hacer avanza;
    gira-izquierda;
    si frente-libre entonces avanza;
    gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-derecha;
fin;
define-nueva-instruccion mide-mitad como
inicio
    si frente-libre o izquierda-libre entonces
    inicio
        si frente-bloqueado y izquierda-libre entonces
        inicio
            cruzar-pared;
        fin
        sino inicio
            si frente-libre entonces avanza;
        fin;
        si frente-bloqueado y izquierda-libre entonces
        inicio
            cruzar-pared;
        fin
        sino inicio
            si frente-libre entonces avanza;
        fin;
        mide-mitad;
        si frente-bloqueado entonces
        inicio
            cruzar-dos;
        fin
        sino inicio
            avanza;
        fin;
    fin
    sino inicio
            gira-derecha;
            mientras frente-libre hacer avanza;
            gira-derecha;
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-este hacer gira-izquierda;
        mide-mitad;
        apagate;
    termina-ejecucion
finalizar-programa