iniciar-programa

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin
    fin;

    define-nueva-instruccion salta como inicio
        si orientado-al-este entonces inicio
            norte;
            mientras derecha-bloqueada hacer inicio
                avanza;
            fin;
            este;
            avanza;
            si frente-libre entonces inicio
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
            fin
            sino inicio
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                si izquierda-libre entonces inicio
                    este;
                fin;
            fin;
        fin;
        si orientado-al-oeste entonces inicio
            norte;
            mientras izquierda-bloqueada hacer inicio
                avanza;
            fin;
            oeste;
            avanza;
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            oeste;
        fin;
    fin;

    define-nueva-instruccion buscar como inicio
        norte;
        mientras frente-libre y derecha-bloqueada hacer inicio
            avanza;
        fin;
        si derecha-libre entonces inicio
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin
        sino inicio
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion mitad como inicio
        si frente-libre o izquierda-libre y no-orientado-al-sur entonces inicio
            buscar;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                salta;
            fin;
            buscar;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                salta;
            fin;
            buscar;
            mitad;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                salta;
            fin;
        fin
        sino inicio
            oeste;
        fin;
    fin;

    inicia-ejecucion
        este;
        mitad;
        apagate;
    termina-ejecucion
finalizar-programa
