iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion contar como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            repetir 2 veces
            inicio
                si frente-libre entonces avanza sino
                    inicio
                        norte;
                        si frente-libre entonces
                        inicio
                            mientras derecha-bloqueada y frente-libre hacer avanza;
                            este;
                            si frente-libre entonces avanza sino sal-de-instruccion;
                        fin sino
                        inicio
                            sur;
                            mientras izquierda-bloqueada y frente-libre hacer avanza;
                            este;
                            si frente-libre entonces avanza sino sal-de-instruccion;
                        fin;
                   fin;
            fin;
            contar;
            si frente-libre entonces avanza sino
            inicio
                norte;
                si frente-libre entonces
                inicio
                    mientras izquierda-bloqueada y frente-libre hacer avanza;
                    oeste;
                    si frente-libre entonces avanza sino sal-de-instruccion;
                    si frente-bloqueado entonces
                    inicio
                        sur;
                        mientras frente-libre hacer avanza;
                    fin;
                fin sino
                inicio
                    sur;
                    mientras derecha-bloqueada y frente-libre hacer avanza;
                    oeste;
                    si frente-libre entonces avanza sino sal-de-instruccion;
                fin;
           fin;
        fin sino
        inicio
            sur;
            mientras frente-libre hacer avanza;
            oeste;
        fin;
    fin;

    inicia-ejecucion
        este;
        contar;
        sur;
        mientras frente-libre hacer avanza;
        apagate;
    termina-ejecucion
finalizar-programa
