iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion corre como inicio
        mientras frente-libre hacer avanza;
    fin;
    define-nueva-instruccion camina como inicio
        si frente-bloqueado entonces inicio
            norte;
            mientras derecha-bloqueada y frente-libre hacer avanza;
            este;
            avanza;
            sur;
            corre;
            este;
        fin sino inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        si frente-bloqueado entonces inicio
            norte;
            mientras izquierda-bloqueada y frente-libre hacer avanza;
            oeste;
            avanza;
            sur;
            corre;
            oeste;
        fin sino inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion mitad como inicio
        si frente-libre entonces inicio
            sur;
            corre;
            este;
            repetir 2 veces camina;
            norte;
            mientras derecha-bloqueada y frente-libre hacer avanza;
            este;
            mitad;
            regresa;
        fin sino inicio
            sur;
            corre;
            oeste;
        fin;
    fin;
    inicia-ejecucion
        norte;
        mientras derecha-bloqueada y frente-libre hacer avanza;
        este;
        mitad;
        apagate;
    termina-ejecucion
finalizar-programa