iniciar-programa
    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion orientar-al-este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
    define-nueva-instruccion salta como inicio
        si izquierda-libre entonces inicio
            gira-izquierda;
            mientras derecha-bloqueada y frente-libre hacer avanza;
            si derecha-libre entonces inicio
                    gira-derecha;
                    avanza;
                    si frente-bloqueado entonces inicio
                        gira-derecha;
                        avanza;
                        mientras derecha-bloqueada y frente-libre hacer avanza;
                        gira-izquierda;                                                                                                                        
                    fin;
            fin
            sino inicio
                gira-izquierda;
                gira-izquierda;
                mientras frente-libre hacer avanza;
            fin;
        fin
        sino inicio
            si derecha-libre entonces inicio
                gira-derecha;
                mientras izquierda-bloqueada y frente-libre hacer avanza;
                si izquierda-libre entonces inicio
                        gira-izquierda;
                        avanza;
                        si frente-bloqueado entonces inicio
                            gira-izquierda;
                            avanza;
                            mientras izquierda-bloqueada y frente-libre hacer avanza;
                            gira-derecha;
                        fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        si frente-libre entonces inicio
            avanza;
        fin
        sino inicio
            si derecha-libre entonces inicio
                salta;
            fin
            sino inicio
                si izquierda-libre entonces inicio
                    salta;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion pasos como inicio
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces inicio
                avanza;
                pasos;
                regresa;
            fin
            sino inicio
                si izquierda-libre entonces inicio
                    salta;
                    pasos;
                    regresa;
                fin
                sino inicio
                    si derecha-libre entonces inicio
                        salta;
                        pasos;
                        regresa;
                    fin;
                fin;
            fin;
        fin
        sino inicio
            si izquierda-libre entonces inicio
                salta;
                si frente-libre entonces inicio
                    avanza;
                    pasos;
                    regresa;
                fin
                sino inicio
                    si izquierda-libre entonces inicio
                        salta;
                        pasos;
                        regresa;
                    fin;
                fin;
            fin
            sino inicio
                si derecha-libre entonces inicio
                    salta;
                    si frente-libre entonces inicio
                        avanza;
                        pasos;
                        regresa;
                    fin;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orientar-al-este;
        pasos;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        apagate;
    termina-ejecucion
finalizar-programa
