iniciar-programa
define-nueva-instruccion gira(a) como inicio
    repetir a veces inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion sur como inicio
    mientras no-orientado-al-sur hacer inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion toca-pared como inicio
    mientras frente-libre hacer inicio
        avanza;
    fin;
fin;
define-nueva-instruccion calcula como inicio
    repetir 5 veces deja-zumbador;
    gira(3);
    mientras no-orientado-al-oeste hacer inicio
        si izquierda-bloqueada y frente-bloqueado entonces inicio
            repetir 5 veces deja-zumbador;
        fin
        sino inicio
            si derecha-libre entonces inicio
                avanza;
                si derecha-bloqueada entonces inicio
                    gira(2);
                    avanza;
                    gira(2);
                    repetir 5 veces deja-zumbador;
                fin
                sino inicio
                    gira(2);
                    avanza;
                    gira(2);
                fin;
            fin;
        fin;
        gira(3);
    fin;
fin;
define-nueva-instruccion llena como inicio
    mientras frente-libre y izquierda-bloqueada hacer inicio
        avanza;
    fin;
    si frente-bloqueado y (orientado-al-oeste y izquierda-bloqueada) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                repetir 4 veces coge-zumbador;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    calcula;
                    apagate;
                fin
                sino inicio
                    repetir 10 veces deja-zumbador;
                    gira(3);
                fin;
            fin
            sino inicio
                calcula;
                apagate;
            fin;
        fin
        sino inicio
            repetir 5 veces deja-zumbador;
            gira(3);
        fin;
    fin
    sino inicio
        si izquierda-bloqueada entonces inicio
            gira(3);
            si izquierda-bloqueada y (orientado-al-oeste y junto-a-zumbador) entonces inicio
                si frente-bloqueado entonces inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    calcula;
                    apagate;
                fin;
            fin;
            repetir 5 veces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                gira(3);
                repetir 5 veces deja-zumbador;
            fin;
        fin
        sino inicio
            repetir 5 veces deja-zumbador;
            gira-izquierda;
            avanza;
        fin;
    fin;
    llena;
fin;
    inicia-ejecucion
        repetir 1 veces deja-zumbador;
        llena;
        apagate;
    termina-ejecucion
finalizar-programa
