iniciar-programa
define-nueva-instruccion checa como
inicio
            repetir 4 veces coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    checa;
                    repetir 5 veces deja-zumbador;
                fin
                sino
                inicio
                    repetir 5 veces deja-zumbador;
                fin;
            fin
            sino
            inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir 4 veces
                inicio
                    si frente-bloqueado y derecha-bloqueada entonces repetir 5 veces deja-zumbador;
                    gira-izquierda;
                fin;
                apagate;
            fin;
fin;
    define-nueva-instruccion recorre como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            si frente-libre y derecha-bloqueada entonces
            inicio
                avanza;
            fin
            sino
            inicio
                si frente-bloqueado y derecha-bloqueada entonces
                inicio
                    gira-izquierda;
                    repetir 5 veces deja-zumbador;
                fin
                sino
                inicio
                    repetir 5 veces deja-zumbador;
                    repetir 3 veces gira-izquierda;
                    avanza;
                fin;
            fin;
            recorre;
        fin
        sino
        inicio
            si frente-libre y derecha-bloqueada entonces
            inicio
                checa;
                avanza;
            fin
            sino
            inicio
                si frente-bloqueado y derecha-bloqueada entonces
                inicio
                    gira-izquierda;
                    deja-zumbador;
                    si no algun-zumbador-en-la-mochila entonces apagate;
                    repetir 4 veces deja-zumbador;
                    checa;
                fin
                sino
                inicio
                    deja-zumbador;
                    si no algun-zumbador-en-la-mochila entonces apagate;
                    repetir 4 veces deja-zumbador;
                    repetir 3 veces gira-izquierda;
                    checa;
                    avanza;
                fin;
            fin;
            recorre;
        fin;
    fin;
    define-nueva-instruccion fn como
    inicio
        mientras no(izquierda-bloqueada y frente-bloqueado) hacer
        inicio
        si izquierda-bloqueada entonces
        inicio
            avanza;
        fin
        sino
        inicio
            gira-izquierda;
            avanza;
            repetir 3 veces gira-izquierda;
        fin;
        fin;
        gira-izquierda;
    fin;
    inicia-ejecucion
    fn;
    mientras no orientado-al-norte hacer
    inicio
        repetir 2 veces gira-izquierda;
        mientras izquierda-bloqueada y frente-libre hacer avanza;
        si izquierda-libre entonces
        inicio
            gira-izquierda;
            avanza;
            fn;
        fin
        sino
        inicio
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir 3 veces gira-izquierda;
        fin;
    fin;
        repetir 4 veces
        inicio
            si frente-bloqueado y derecha-bloqueada entonces repetir 5 veces deja-zumbador;
            gira-izquierda;
        fin;
        si junto-a-zumbador entonces coge-zumbador;
        repetir 4 veces
        inicio
            si junto-a-zumbador entonces
            inicio
                si frente-libre y derecha-bloqueada entonces
                inicio
                    avanza;
                fin
                sino
                inicio
                    gira-izquierda;
                fin;
            fin;
        fin;
        si no junto-a-zumbador entonces
        inicio
            recorre;
        fin;
        deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa

