iniciar-programa
    define-prototipo-instruccion recorre;
    define-nueva-instruccion deja(n) como repetir n veces deja-zumbador;
    define-nueva-instruccion toma(n) como repetir n veces coge-zumbador;
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion checa como inicio
        si junto-a-zumbador entonces toma(4);
        si junto-a-zumbador entonces inicio
            deja(4);
            recorre;
        fin;
        si no-junto-a-zumbador entonces inicio
            deja(5);
            si izquierda-bloqueada entonces deja(5);
            apagate;
        fin;
    fin;

    define-nueva-instruccion recorre como inicio
        mientras frente-libre y izquierda-bloqueada hacer avanza;
        si junto-a-zumbador entonces inicio
            toma(4);
            si no-junto-a-zumbador entonces inicio
                deja(5);
                si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces deja(5);
                apagate;
            fin;
            si junto-a-zumbador entonces deja(4);
        fin;
        deja(5);
        si frente-bloqueado y izquierda-bloqueada entonces inicio
            gira(3);
            checa;
        fin;
        si izquierda-libre entonces inicio
            gira(1);
            avanza;
            si junto-a-zumbador entonces checa;
        fin;
        si no-junto-a-zumbador entonces recorre;
    fin;

    inicia-ejecucion
        si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
            deja(20);
            apagate;
        fin sino inicio
            deja(4);
            recorre;
            apagate;
        fin;
    termina-ejecucion
finalizar-programa
