iniciar-programa
    define-prototipo-instruccion recorre(x) ;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            corre;
            norte;
            si frente-libre entonces inicio
                avanzA;
                este;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion menor(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            menor(precede(x));
            deja-zumbador;
        fin sino inicio
            si no si-es-cero(x) entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                oeste;
            fin sino inicio
                este;
            fin;
        fin;
    fin;
    define-nueva-instruccion ve100 como inicio
        corre;
        sur;
        corre;
        este;
        mientras no-junto-a-zumbador hacer camina;
        repetir 100 veces coge-zumbador;
        mientras no-junto-a-zumbador hacer camina;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir 100 veces deja-zumbador;
    fin;
    define-nueva-instruccion leer-nuevo(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            leer-nuevo(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            ve100;
            camina;
            recorre(x);
        fin;
    fin;
    define-nueva-instruccion recorre(x) como inicio
        si no-orientado-al-sur entonces inicio
            si junto-a-zumbador entonces inicio
                menor(x);
                si orientado-al-oeste entonces inicio
                    leer-nuevo(0);
                fin sino inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    camina;
                    recorre(x);
                fin;
            fin sino inicio
                camina;
                recorre(x);
            fin;
        fin;
    fin;
    define-nueva-instruccion primero(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            primero(sucede(x));
        fin sino inicio
            repetir 100 veces deja-zumbador;
            camina;
            recorre(x);
        fin;
    fin;
    inicia-ejecucion
        oeste;
        corre;
        sur;
        corre;
        este;
        primero(0);
        corre;
        este;
        mientras no-junto-a-zumbador hacer camina;
        apagate;
    termina-ejecucion
finalizar-programa
