iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion orientar como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion compara(n) como inicio
        si orientado-al-norte o orientado-al-sur entonces inicio
            repetir n veces inicio
                si junto-a-zumbador y (orientado-al-norte o orientado-al-sur) entonces inicio
                    coge-zumbador;
                fin
                sino inicio
                    si orientado-al-norte o orientado-al-sur entonces gira-izquierda;
                    deja-zumbador;
                fin;
            fin;
        fin;
        si orientado-al-norte o orientado-al-sur entonces inicio
                repetir n veces deja-zumbador;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara(n);
                coge-zumbador;
            fin
            sino inicio
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca como inicio
      mientras junto-a-zumbador hacer inicio
        si frente-libre entonces inicio
           avanza;
        fin
        sino inicio
            si orientado-al-norte y izquierda-libre entonces inicio
                gira-izquierda;
                avanza;
                gira-izquierda;
            fin
            sino inicio
                si orientado-al-sur y derecha-libre entonces inicio
                    gira(3);
                    avanza;
                    gira(3);
                fin;
            fin;
        fin;
      fin;
        repetir 100 veces deja-zumbador;
        apagate;
    fin;

    define-nueva-instruccion encuentra(n) como inicio
        si frente-libre entonces inicio
            avanza;
            compara(n);
            si orientado-al-norte o orientado-al-sur entonces inicio
                encuentra(n);
            fin
            sino inicio
                gira(3);
            fin;
        fin
        sino inicio
            si orientado-al-norte y derecha-libre entonces inicio
                gira(3);
                avanza;
                gira(3);
                compara(n);
                si orientado-al-norte o orientado-al-sur entonces inicio
                    encuentra(n);
                fin
                sino inicio
                    gira(3);
                fin;
            fin
            sino inicio
                si orientado-al-sur y izquierda-libre entonces inicio
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                    compara(n);
                    si orientado-al-norte o orientado-al-sur entonces inicio
                        encuentra(n);
                    fin
                    sino inicio
                        gira(3);
                    fin;
                fin
                sino inicio
                    gira(2);
                    busca;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion min(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            min(sucede(n));
        fin
        sino inicio
            encuentra(n);
        fin;
    fin;

    inicia-ejecucion
        orientar;
        mientras algun-zumbador-en-la-mochila hacer min(0);
        apagate;
    termina-ejecucion
finalizar-programa
