iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    gira-izquierda;
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion media-vuelta como
inicio
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion encontrar(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        mientras frente-libre o derecha-libre hacer
        inicio
            repetir n veces coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                repetir n veces deja-zumbador;
            fin
            sino inicio
                repetir 100 veces deja-zumbador;
                apagate;
            fin;
            si frente-libre entonces
            inicio
                avanza;
            fin
            sino inicio
                media-vuelta;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                si frente-libre entonces avanza;
                gira-izquierda;
            fin;
        fin;
        si orientado-al-norte y frente-bloqueado y derecha-bloqueada entonces
        inicio
            repetir n veces coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                repetir n veces deja-zumbador;
            fin
            sino inicio
                repetir 100 veces deja-zumbador;
                apagate;
            fin;
        fin;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-derecha;
        encontrar(sucede(n));
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        media-vuelta;
        si orientado-al-norte y frente-bloqueado y derecha-bloqueada y no-junto-a-zumbador entonces
        inicio
            repetir 100 veces deja-zumbador;
            apagate;
        fin;
        encontrar(0);
        apagate;
    termina-ejecucion
finalizar-programa 