iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion cien como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces
                        deja-zumbador;
                fin
                sino inicio
                repetir 101 veces
                    deja-zumbador;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            deja-zumbador;
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    cien;
                    gira(2);
                    avanza;
                    gira(2);
                fin;
                gira(1);
            fin;
        fin;
    fin;
    define-nueva-instruccion unos como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 3 veces
                        deja-zumbador;
                fin
                sino inicio
                    repetir 3 veces
                        deja-zumbador;
                fin;
            fin
            sino inicio
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                        avanza;
                        unos;
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                    gira(1);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                  coge-zumbador;
                  si junto-a-zumbador entonces inicio
                     deja-zumbador;
                     deja-zumbador;
                  fin
                  sino inicio
                     deja-zumbador;
                     deja-zumbador;
                     sal-de-instruccion;
                  fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
        regresa;
    fin;
    define-nueva-instruccion checate_esto como inicio
        si frente-libre entonces inicio
            mientras frente-libre hacer inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            repetir 3 veces
                                deja-zumbador;
                        fin
                        sino inicio
                            repetir 3 veces
                                deja-zumbador;
                            gira(2);
                            regresa;
                            repetir 2 veces
                                coge-zumbador;
                            gira(2);
                            sal-de-instruccion;
                        fin;
                    fin
                    sino inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
            gira(2);
            regresa;
            gira(2);
        fin;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            compara(precede(n));
            si junto-a-zumbador entonces
                deja-zumbador;
        fin
        sino inicio
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin
            sino inicio
                mientras junto-a-zumbador hacer
                    coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion exaustiva(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 98 veces
                       coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        compara(n);
                        si junto-a-zumbador entonces inicio
                            coge-zumbador
                        fin
                        sino inicio
                            repetir n veces
                               deja-zumbador;
                        fin;
                    fin
                    sino inicio
                        repetir n veces
                            deja-zumbador;
                    fin;
                    repetir 101 veces
                        deja-zumbador;
                fin
                sino inicio
                    repetir 3 veces
                        deja-zumbador;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            repetir 2 veces
                deja-zumbador;
            repetir 4 veces inicio
                si junto-a-zumbador entonces
                    checate_esto;
                gira(1);
            fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                         avanza;
                         exaustiva(n);
                         gira(2);
                         avanza;
                         gira(2);
                    fin;
                    gira(1);
                fin;
                coge-zumbador;
            fin
            sino inicio
                deja-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                         avanza;
                         exaustiva(sucede(n));
                         gira(2);
                         avanza;
                         gira(2);
                    fin;
                    gira(1);
                fin;
                coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion finaliza(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            finaliza(precede(n));
            deja-zumbador;
        fin
        sino inicio
            si si-es-cero(n) y no-junto-a-zumbador entonces inicio
                deja-zumbador;
                apagate;
            fin;
        fin;
    fin;
    define-nueva-instruccion exaustivafinal(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 98 veces
                       coge-zumbador;
                        finaliza(n);
                    repetir 101 veces
                        deja-zumbador;
                fin
                sino inicio
                    repetir 3 veces
                        deja-zumbador;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            repetir 2 veces
                deja-zumbador;
            repetir 4 veces inicio
                si junto-a-zumbador entonces
                    checate_esto;
                gira(1);
            fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                         avanza;
                         exaustivafinal(n);
                         gira(2);
                         avanza;
                         gira(2);
                    fin;
                    gira(1);
                fin;
                coge-zumbador;
            fin
            sino inicio
                deja-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                         avanza;
                         exaustivafinal(sucede(n));
                         gira(2);
                         avanza;
                         gira(2);
                    fin;
                    gira(1);
                fin;
                coge-zumbador;
            fin;
        fin;
    fin;
    inicia-ejecucion
        cien;
        unos;
        exaustiva(0);
        exaustivafinal(0);
        apagate;
    termina-ejecucion
finalizar-programa
