iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
define-nueva-instruccion cuenta1(n) como inicio
    norte;
    si frente-libre entonces inicio
        avanza;
        si frente-libre y junto-a-zumbador entonces inicio
            cuenta1(sucede(n));
        fin sino inicio
            norte;
            avanzar;
            repetir n veces deja-zumbador;
            sur;
            si frente-libre entonces avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta2(n) como inicio
    norte;
    si frente-libre entonces inicio
        avanza;
        si frente-libre y junto-a-zumbador entonces inicio
            cuenta2(sucede(n));
        fin sino inicio
            norte;
            avanzar;
            oeste;
            avanza;
            repetir n veces deja-zumbador;
            sur;
            si frente-libre entonces avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta3(n) como inicio
    norte;
    si frente-libre entonces inicio
        avanza;
        si frente-libre y junto-a-zumbador entonces inicio
            cuenta3(sucede(n));
        fin sino inicio
            norte;
            avanzar;
            este;
            avanza;
            repetir n veces deja-zumbador;
            sur;
            si frente-libre entonces avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion marca como inicio
    sur;
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces inicio
        si frente-libre entonces inicio
            cuenta1(2);
        fin sino inicio
            cuenta1(1);
        fin;
    fin;
    este;
    si frente-libre entonces inicio
        avanza;
        sur;
        si junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                cuenta2(2);
            fin sino inicio
                cuenta2(1);
            fin;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanzar;
                    oeste;
                    avanza;
                    deja-zumbador;
                    este;
                    avanza;
                fin;
                norte;
                avanzar;
                oeste;
                avanza;
                sur;
                si frente-libre entonces avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin;
        fin;
    fin;
    oeste;
    si frente-libre entonces inicio
        avanza;
        sur;
        si junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                cuenta3(2);
            fin sino inicio
                cuenta3(1);
            fin;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanzar;
                    este;
                    avanza;
                    deja-zumbador;
                    oeste;
                    avanza;
                fin;
                norte;
                avanzar;
                este;
                avanza;
                sur;
                si frente-libre entonces avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin sino inicio
                norte;
                avanzar;
                este;
                avanza;
            fin;
        fin;
    fin;
    norte;
    avanzar;
    este;
    si frente-libre entonces inicio
        avanza;
        marca;
    fin;
fin;
define-nueva-instruccion cuenta(n) como inicio
    si junto-a-zumbador y orientado-al-oeste entonces inicio
        coge-zumbador;
        cuenta(sucede(n));
    fin sino inicio
        repetir n veces deja-zumbador;
        si frente-libre entonces inicio
            avanza;
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador y orientado-al-oeste entonces inicio
                cuenta(0);
            fin sino inicio
                norte;
            fin;
        fin sino inicio
            norte;
        fin;
        si orientado-al-norte entonces inicio
            sur;
            avanza;
            este;
            avanzar;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
        si no si-es-cero(n) entonces inicio
            si no-junto-a-zumbador entonces inicio
                repetir n veces deja-zumbador;
            fin sino inicio
                repetir n veces inicio
                    si junto-a-zumbador entonces coge-zumbador;
                fin;
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion busca(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        busca(sucede(n));
    fin sino inicio
        norte;
        avanza;
        oeste;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            este;
            avanzar;
            apagate;
        fin;
        mientras orientado-al-oeste hacer inicio
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin sino inicio
                    norte;
                fin;
            fin;
            si orientado-al-norte entonces inicio
                oeste;
                avanza;
            fin sino inicio
                repetir n veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;
fin;
    inicia-ejecucion
    marca;
    oeste;
    cuenta(0);
    busca(0);
        apagate;
    termina-ejecucion
finalizar-programa
