iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion avanzar como inicio
        sur;
        si frente-libre entonces inicio
            avanza;
            mientras frente-libre y no junto-a-zumbador hacer avanza;
            si frente-libre entonces avanza;
            norte;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            cuenta(sucede(n));
        fin sino inicio
            mientras frente-libre hacer avanza;
            este;
            avanza;
            repetir n veces deja-zumbador;
            avanzar;
        fin;
    fin;
    define-nueva-instruccion cuenta2(n) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            cuenta2(sucede(n));
        fin sino inicio
            mientras frente-libre hacer avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cuenta3(n) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            cuenta3(sucede(n));
        fin sino inicio
            mientras frente-libre hacer avanza;
            oeste;
            avanza;
            repetir n veces deja-zumbador;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion guajolojet como inicio
        avanzar;
        oeste;
        si frente-libre entonces inicio
            avanza;
            norte;
            cuenta(0);
        fin;
        norte;
        cuenta2(0);
        este;
        si frente-libre entonces inicio
            avanzar;
            este;
            avanza;
            norte;
            cuenta3(0);
        fin sino inicio
            oeste;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces coge-zumbador;
        fin;
        si no junto-a-zumbador entonces inicio
            este;
            mientras frente-libre hacer avanza;
            oeste;
        fin sino inicio
            repetir n veces deja-zumbador;
            este;
            avanza;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            oeste;
        fin;
    fin;

    define-nueva-instruccion coge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces inicio
                    compara(n);
                fin sino inicio
                    este;
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                    apagate;
                fin;
            fin sino inicio
                este;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        mientras no orientado-al-oeste hacer inicio
            guajolojet;
        fin;
        mientras no orientado-al-este hacer inicio
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            coge(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
