iniciar-programa
    define-prototipo-instruccion mayor(x);
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;
    define-nueva-instruccion corre como inicio
        mientras frente-libre hacer avanza;
    fin;
    define-nueva-instruccion izquierda como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            izquierda;
            deja-zumbador;
        fin sino inicio
            corre;
            repetir 3 veces gira-izquierda;
            avanza;
        fin;
    fin;
    define-nueva-instruccion derecha como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            derecha;
            deja-zumbador;
        fin sino inicio
            corre;
            gira-izquierda;
            avanza;
        fin;
    fin;
    define-nueva-instruccion cuenta como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            cuenta;
            deja-zumbador;
        fin sino inicio
            corre;
        fin;
    fin;
    define-nueva-instruccion destruccion como inicio
        mientras no-orientado-al-oeste hacer inicio
            sur;
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si frente-libre entonces avanza;
            oeste;
            si frente-libre entonces inicio
                avanza;
                norte;
                izquierda;
                sur;
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer avanza;
                si frente-libre entonces avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
                derecha;
                sur;
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer avanza;
                si frente-libre entonces avanza;
            fin;
            norte;
            cuenta;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion agarra(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            agarra(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                este;
            fin;
            mayor(x);
        fin;
    fin;
    define-nueva-instruccion compara(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            compara(precede(x));
        fin sino inicio
            si no-junto-a-zumbador y si-es-cero(x) entonces inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion responde(x) como inicio
        mientras no-orientado-al-sur hacer inicio
            compara(x);
            si no-orientado-al-sur entonces inicio
                avanza;
            fin;
        fin;
        este;
        repetir x veces deja-zumbador;
    fin;
    define-nueva-instruccion mayor(x) como inicio
        si no-orientado-al-este entonces inicio
            repetir x veces si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
            repetir x veces deja-zumbador;
            agarra(0);
        fin sino inicio
            este;
            corre;
            oeste;
            responde(x);
        fin;
    fin;
    inicia-ejecucion
        destruccion;
        mayor(0);
        apagate;
    termina-ejecucion
finalizar-programa
