iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion mide-izquierdo como inicio
        si (junto-a-zumbador y  frente-libre ) entonces inicio
            avanza;
            mide-izquierdo;
            deja-zumbador;
        fin sino inicio
            mientras frente-libre hacer avanza;
            gira(3);
            avanza;
        fin;
    fin;

    define-nueva-instruccion mide-derecho como inicio
        si (junto-a-zumbador y  frente-libre ) entonces inicio
            avanza;
            mide-derecho;
            deja-zumbador;
        fin sino inicio
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
        fin;
    fin;

    define-nueva-instruccion mide-centro como inicio
        si (junto-a-zumbador y  frente-libre ) entonces inicio
            avanza;
            mide-centro;
            deja-zumbador;
        fin sino inicio
            mientras frente-libre hacer avanza;
        fin;
    fin;

    define-nueva-instruccion mide como inicio
        mientras no-orientado-al-sur hacer gira(1);
        mientras (no-junto-a-zumbador y frente-libre) hacer avanza;
        si frente-libre entonces avanza;
        gira(2);
        mide-centro;

        mientras no-orientado-al-sur hacer gira(1);
        si frente-libre entonces avanza;
        mientras (no-junto-a-zumbador y frente-libre) hacer avanza;
        si frente-libre entonces avanza;
        gira(3);
        si frente-libre entonces inicio
            avanza;
            gira(3);
            mide-izquierdo;

            mientras no-orientado-al-sur hacer gira(1);
            si frente-libre entonces avanza;
            mientras (no-junto-a-zumbador y frente-libre) hacer avanza;
            si frente-libre entonces avanza;
            gira(1);
        fin sino inicio
            gira(2);
        fin;

        si frente-libre entonces inicio
            avanza;
            gira(1);
            mide-derecho;
            mientras no-orientado-al-este hacer gira(1);
            si frente-libre entonces avanza;
        fin;
    fin;

    define-nueva-instruccion esquina-izquierda como inicio
        mientras no-orientado-al-norte hacer gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(n));
        fin sino inicio
            deja-zumbador;
            avanza;
            mientras (no-junto-a-zumbador y frente-libre) hacer avanza;
            si (frente-bloqueado y no-junto-a-zumbador) entonces inicio
                gira(2);
                mientras no-junto-a-zumbador hacer avanza;
                repetir precede(n) veces deja-zumbador;
                apagate;
            fin;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            si no-junto-a-zumbador entonces inicio
                gira(2);
                mientras no-junto-a-zumbador hacer avanza;
                repetir precede(n) veces deja-zumbador;
                gira(2);
            fin sino inicio
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        mientras frente-libre hacer mide;
        mide;
        esquina-izquierda;
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces inicio
                compara(0);
            fin sino inicio
                avanza;
                si frente-bloqueado entonces inicio
                    gira(2);
                    mientras frente-libre hacer avanza;
                fin;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
