iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion destruccion-sur como inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                repetir 2 veces deja-zumbador;
            fin sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                deja-zumbador;
            fin;
        fin sino inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
        fin;
    fin;
    define-nueva-instruccion destruccion-oeste(n) como inicio
        si junto-a-zumbador y frente-libre y orientado-al-norte entonces inicio
            si frente-libre entonces avanza;
            destruccion-oeste(sucede(n));
        fin;
        si no-junto-a-zumbador y frente-libre y orientado-al-norte entonces inicio
            mientras frente-libre hacer avanza;
        fin;
        si frente-bloqueado y orientado-al-norte entonces inicio
            gira(3);
            si frente-libre entonces avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion destruccion-este(n) como inicio
        si junto-a-zumbador y frente-libre y orientado-al-norte entonces inicio
            si frente-libre entonces avanza;
            destruccion-este(sucede(n));
        fin;
        si no-junto-a-zumbador y frente-libre y orientado-al-norte entonces inicio
            mientras frente-libre hacer avanza;
        fin;
        si frente-bloqueado y orientado-al-norte entonces inicio
            gira(1);
            si frente-libre entonces avanza;
            repetir n veces deja-zumbador;
            gira(2);
        fin;
    fin;
    define-nueva-instruccion bomba como inicio
        si orientado-al-este y no-junto-a-zumbador y izquierda-bloqueada entonces inicio
            gira(3);
            destruccion-sur;
            si frente-libre entonces inicio
                gira(1);
                si frente-libre entonces avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador y frente-libre entonces avanza;
                gira(3);
                si frente-libre entonces avanza;
                gira(3);
                si junto-a-zumbador entonces destruccion-oeste(0) sino inicio
                    mientras frente-libre hacer avanza;
                    gira(3);
                    si frente-libre entonces avanza;
                fin;
            fin sino gira(2);
            si frente-libre entonces inicio
                gira(3);
                si frente-libre entonces avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador y frente-libre entonces avanza;
                gira(1);
                si frente-libre entonces avanza;
                gira(1);
                si junto-a-zumbador entonces destruccion-este(0) sino inicio
                    mientras frente-libre hacer avanza;
                    gira(1);
                    si frente-libre entonces avanza;
                    gira(2);
                fin;
            fin;
            si frente-libre entonces inicio
                avanza;
                bomba;
            fin;
        fin;
    fin;
    define-nueva-instruccion mayor-destruccion(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor-destruccion(sucede(n));
        fin;
        si no-junto-a-zumbador y frente-libre entonces inicio
            repetir n veces deja-zumbador;
            si frente-libre entonces avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            si junto-a-zumbador entonces inicio
                repetir n veces deja-zumbador;
                gira(2);
                si frente-libre entonces avanza;
                mientras frente-libre hacer inicio
                    si no-junto-a-zumbador y frente-libre entonces avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                fin;
                mientras junto-a-zumbador hacer coge-zumbador;
                gira(2);
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin sino si frente-libre entonces inicio
                gira(2);
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin;
        fin;
    fin;
inicia-ejecucion
    bomba;
    gira(2);
    mientras frente-libre hacer inicio
        mayor-destruccion(0);
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;
    gira(2);
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
        apagate;
    termina-ejecucion
finalizar-programa
