iniciar-programa
define-nueva-instruccion g(n) como
    repetir n veces gira-izquierda;
define-nueva-instruccion cuentai(n) como
inicio
    si junto-a-zumbador y frente-libre entonces
    inicio
        avanza;
        cuentai(sucede(n));
    fin
    sino
    inicio
        mientras frente-libre hacer avanza;
        g(3);
        avanza;
        repetir n veces deja-zumbador;
        g(3);
    fin;
fin;
define-nueva-instruccion cuentad(n) como
inicio
    si junto-a-zumbador y frente-libre entonces
    inicio
        avanza;
        cuentad(sucede(n));
    fin
    sino
    inicio
        mientras frente-libre hacer avanza;
        gira-izquierda;
        avanza;
        repetir n veces deja-zumbador;
        g(2);
    fin;
fin;
define-nueva-instruccion cuenta(n) como
inicio
    si junto-a-zumbador y frente-libre entonces
    inicio
        avanza;
        cuenta(sucede(n));
    fin
    sino
    inicio
        mientras frente-libre hacer avanza;
        repetir n veces deja-zumbador;
        g(2);
    fin;
fin;
define-nueva-instruccion max(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        max(sucede(n));
    fin
    sino
    inicio
        repetir n veces deja-zumbador;
        si frente-bloqueado entonces
        inicio
            g(2);
            mientras frente-libre hacer avanza;
            g(2);
            mientras frente-libre o frente-bloqueado hacer
            inicio
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                si frente-bloqueado y no-junto-a-zumbador entonces
                inicio
                    g(2);
                    mientras frente-libre hacer avanza;
                    apagate;
                fin;     
                repetir precede(n) veces
                    si junto-a-zumbador entonces coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    repetir precede(n) veces deja-zumbador;
                    apagate;
                fin;
            fin;
            apagate;
        fin;
        avanza;
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        repetir n veces
            si junto-a-zumbador entonces coge-zumbador;
        max(n);
    fin;
fin;
    inicia-ejecucion
    si derecha-bloqueada entonces apagate;
    g(3);
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-libre entonces avanza;
    g(2);
    cuenta(0);
    avanza;
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-libre entonces avanza;
    gira-izquierda;
    si frente-libre entonces
        avanza
    sino
        apagate;
    gira-izquierda;
    cuentad(0);
    avanza;
    mientras frente-libre hacer
    inicio
        g(3);
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si frente-libre entonces avanza;
        g(3);
        avanza;
        g(3);
        cuentai(0);
        avanza;
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si frente-libre entonces avanza;
        g(2);
        cuenta(0);
        avanza;
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si frente-libre entonces avanza;
        gira-izquierda;
        avanza;
        gira-izquierda;
        cuentad(0);
        avanza;
    fin;
    g(3);
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-libre entonces avanza;
    g(3);
    avanza;
    g(3);
    cuentai(0);
    avanza;
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-libre entonces avanza;
    g(2);
    cuenta(0);
    g(3);
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    max(0);
        apagate;
    termina-ejecucion
finalizar-programa
