iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierdA;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierdA;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierdA;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierdA;

    define-nueva-instruccion contar-norte como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            contar-norte;
            deja-zumbador;
        fin sino inicio
            norte;
            mientras frente-libre hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar-este como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            contar-este;
            deja-zumbador;
        fin sino inicio
            norte;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            oeste;
            avanza;
        fin;
    fin;

    define-nueva-instruccion contar-oeste como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            contar-oeste;
            deja-zumbador;
        fin sino inicio
            norte;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion bajar como inicio
        sur;
        avanza;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si frente-libre entonces avanza;
    fin;

    define-nueva-instruccion edificios como inicio
        bajar;
        oeste;
        si frente-libre entonces inicio
            avanza;
            norte;
            contar-oeste;
            bajar;
        fin;
        norte;
        contar-norte;
        bajar;
        este;
        si frente-libre entonces inicio
            avanza;
            norte;
            contar-este;
        fin sino inicio
            norte;
            mientras frente-libre hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion mayor(n) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            coge-zumbador;
            mayor(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                deja-zumbador;
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer inicio
                    avanza;
                fin;
                repetir n veces si junto-a-zumbador entonces coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    este;
                    mientras no junto-a-zumbador hacer inicio
                        avanza;
                    fin;
                    coge-zumbador;
                    repetir n veces deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                    fin sino inicio
                        norte;
                    fin;
                fin sino inicio
                    repetir n veces inicio
                        deja-zumbador;
                    fin;
                    este;
                    avanza;
                    mientras no junto-a-zumbador hacer inicio
                        avanza;
                    fin;
                    coge-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                    fin sino inicio
                        norte;
                    fin;
                fin;
            fin sino inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    norte;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras no orientado-al-norte hacer inicio
            edificios;
            oeste;
            mayor(0);
        fin;
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        este;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
