iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion colateral como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            colateral;
            deja-zumbador;
        fin
        sino inicio
            mientras frente-libre hacer
                avanza;
            este;
            avanza;
            sur;
        fin;
    fin;
    define-nueva-instruccion colateral2 como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            colateral2;
            deja-zumbador;
        fin
        sino inicio
            mientras frente-libre hacer
                avanza;
            oeste;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion checa como inicio
        si frente-libre entonces inicio
            norte;
            mientras frente-libre hacer
                avanza;
            repetir 2 veces
                deja-zumbador;
            sur;
            avanza;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            avanza;
            oeste;
            si frente-libre entonces inicio
                avanza;
                norte;
                colateral;
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
                colateral2;
            fin;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                norte;
                mientras frente-libre hacer
                    avanza;
                deja-zumbador;
                sur;
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                norte;
                colateral;
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
                colateral2;
            fin;
        fin;
    fin;
    define-nueva-instruccion calcula como inicio
        sur;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        checa;
    fin;
    define-nueva-instruccion cual (n) como inicio
        si no si-es-cero (n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            cual (precede(n));
            deja-zumbador;
        fin
        sino inicio
            si si-es-cero (n) entonces
                oeste;
        fin;
    fin;
    define-nueva-instruccion compara (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                si junto-a-zumbador entonces inicio
                    cual (n);
                    si orientado-al-oeste entonces inicio
                        avanza;
                        mientras frente-libre y no-junto-a-zumbador hacer
                            avanza;
                        mientras junto-a-zumbador hacer
                            coge-zumbador;
                        mientras frente-libre hacer
                            avanza;
                        este;
                    fin
                    sino inicio
                        mientras junto-a-zumbador hacer
                            coge-zumbador;
                        oeste;
                        mientras frente-libre hacer
                            avanza;
                        este;
                    fin;
                fin
                sino inicio
                    gira (2);
                    mientras frente-libre y no-junto-a-zumbador hacer
                        avanza;
                    este;
                    apagate;
                fin;
            fin
            sino inicio
                apagate;
            fin;
        fin;
    fin;
    define-nueva-instruccion mayor como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        si junto-a-zumbador entonces inicio
            compara (0);
            mayor;
        fin
        sino inicio
            apagate;
        fin;
    fin;
    define-nueva-instruccion edificios como inicio
        mientras frente-libre hacer inicio
            calcula;
            avanza;
        fin;
        calcula;
        norte;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        este;
        mayor;
    fin;
    inicia-ejecucion
        edificios;
        apagate;
    termina-ejecucion
finalizar-programa