iniciar-programa
    define-nueva-instruccion gira(n) como inicio
       repetir n veces
          gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer
          gira(1);
    fin;
    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer
          gira(1);
    fin;
    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer
          gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer
          gira(1);
    fin;
    define-nueva-instruccion baja como inicio
       sur;
       si frente-libre entonces
          avanza;
       mientras no-junto-a-zumbador y frente-libre hacer inicio
          avanza;
       fin;
       si frente-libre entonces
          avanza;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
       si junto-a-zumbador y frente-libre entonces inicio
          avanza;
          cuenta(sucede(n));
       fin
       sino inicio
          sur;
          repetir n veces
             avanza;
          repetir n veces
             deja-zumbador;
       fin;
    fin;
    define-nueva-instruccion deja como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          deja;
          deja-zumbador;
       fin
       sino inicio
          deja-zumbador;
          si orientado-al-este o orientado-al-oeste entonces
             avanza;
          norte;
          mientras frente-libre hacer
             avanza;
       fin;
    fin;
    define-nueva-instruccion bomba como inicio
       baja;
       norte;
       cuenta(0);
       norte;
       si junto-a-zumbador entonces inicio
          deja;
          coge-zumbador;
          baja;
       fin;
       este;
       si frente-libre entonces inicio
          avanza;
          norte;
          cuenta(0);
          oeste;
          si junto-a-zumbador entonces inicio
             deja;
             coge-zumbador;
             baja;
          fin
          sino inicio
             oeste;
             avanza;
          fin;
       fin;
       oeste;
       si frente-libre entonces inicio
          avanza;
          norte;
          cuenta(0);
          este;
          si junto-a-zumbador entonces inicio
             deja;
             coge-zumbador;
             baja;
          fin
          sino inicio
             este;
             avanza;
          fin;
       fin;
       norte;
       mientras frente-libre hacer
          avanza;
       este;
    fin;
    define-nueva-instruccion inicia como inicio
       este;
       mientras frente-libre hacer inicio
          bomba;
          avanza;
       fin;
       bomba;
    fin;
    define-nueva-instruccion compara(n) como inicio
       si junto-a-zumbador y no si-es-cero(n) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
       fin
       sino inicio
          si junto-a-zumbador y si-es-cero(n) entonces inicio
             norte;
          fin
          sino inicio
             si no-junto-a-zumbador y si-es-cero(n) entonces inicio
                 sur;
             fin;
          fin;
       fin;
    fin;
    define-nueva-instruccion termina(n) como inicio
       oeste;
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          termina(sucede(n));
       fin
       sino inicio
          repetir n veces
             deja-zumbador;
          este;
          mientras frente-libre hacer
             avanza;
          oeste;
          mientras frente-libre y no-orientado-al-norte hacer inicio
             compara(n);
             si no-orientado-al-norte entonces inicio
                oeste;
                avanza;
             fin;
          fin;
          si no-orientado-al-norte entonces inicio
             compara(n);
          fin;
          si orientado-al-norte entonces inicio
             termina(0);
          fin
          sino inicio
             este;
             mientras frente-libre hacer
                avanza;
             oeste;
             mientras no-orientado-al-sur hacer inicio
                compara(n);
                si no-orientado-al-sur entonces inicio
                   oeste;
                   avanza;
                fin
                sino inicio
                   este;
                   apagate;
                fin;
             fin;
          fin;
       fin;
    fin;
    inicia-ejecucion
        inicia;
        termina(0);
        apagate;
    termina-ejecucion
finalizar-programa